MathGroup Archive 2007

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Foucault pendulum


Hi,

something like this:

fde =
   {x''[t] == -\[Omega]^2*x[t] + 2 \[CapitalOmega]*Sin[\[Phi]]*y'[t] ,
    y''[t] == -\[Omega]^2*y[t] - 2 \[CapitalOmega]*Sin[\[Phi]]*x'[t]};

Block[{\[Omega] = 1, \[CapitalOmega] = 1/16, \[Phi] = Pi/6},
  sol = NDSolve[
    Join[fde, {x[0] == 1, y[0] == 1, x'[0] == 0, y'[0] == 0}],
    {x[t], y[t]}, {t, 0, 64 Pi}]
  ]

pendelPos[{x_, y_}] := {x, y, -Sqrt[10 - x - y]}

pendel[tau_?
    NumericQ] := ({Line[{{0, 0, 0}, pendelPos[{x[t], y[t]}]}],
      Sphere[pendelPos[{x[t], y[t]}], 0.15]} /. sol[[1]]) /. t -> tau

Manipulate[
  DynamicModule[{traj},
   traj = ParametricPlot3D[
     pendelPos[{x[t], y[t]} ] /. sol[[1]], {t, t1, t1 + 4 Pi}
     ];
   Graphics3D[
    {traj[[1]], pendel[t1]}, PlotRange -> {{-2, 2}, {-2, 2}, {-4, 0}}
    ]], {t1, 0, 60 Pi}
  ]

Regards
   Jens

dimitris wrote:
> Hello.
> Does anyone have notebooks
> demonstrating Foucault's pendulum?
> 
> Thanks
> Dimitris
> 
> 


  • Prev by Date: Re: reading from file
  • Next by Date: Matheamatica 6 + Dual G5 = highly unstable??
  • Previous by thread: Re: Foucault pendulum
  • Next by thread: Re: Foucault pendulum