MathGroup Archive 2007

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Can Mathematica do Separation of Variables?

  • To: mathgroup at smc.vnet.net
  • Subject: [mg73016] Re: Can Mathematica do Separation of Variables?
  • From: Paul Abbott <paul at physics.uwa.edu.au>
  • Date: Mon, 29 Jan 2007 04:19:35 -0500 (EST)
  • Organization: The University of Western Australia
  • References: <epf9mr$c44$1@smc.vnet.net>

In article <epf9mr$c44$1 at smc.vnet.net>, "Raj" <rajanikanth at gmail.com> 
wrote:

> Can somebody please tell me if Mathematica can do separation of
> variables (using DSolve)
> 
> for ex: if I give this equation to DSolve, its not able to separate the
> variables
> 
> D[u[x,t],{t,2}]==D[u[x,t],{x,2}]+D[u[x,t],{t,1},{x,2}]

There is no built-in tool for separation of variables. However, for your 
differential equation,

 deq = D[u[x,t],{t,2}] == D[u[x,t],{x,2}]+D[u[x,t],{t,1},{x,2}];

re-writing this as

 deq = Subtract @@ deq

followed by the substitution u -> Function[{x, t}, X[x] T[t]],

 deq /. u -> Function[{x, t}, X[x] T[t]];

and then by dividing through by X[x] (T'[t] + T[t])) generates the 
separated equations:

 Apart[% / (X[x] (T'[t] + T[t]))]

 T''[t]/(T[t] + T'[t]) - X''[x]/X[x]

There is another approach for such equations. One can find travelling 
wave solutions of the form u[x,t] = g[x - v t] as follows:

 deq /. u -> Function[{x, t}, g[x - v t]] // Simplify

 (v^2 - 1) g''[x - v t] + v g'''[x - v t] == 0

Putting x - v t -> z, the solution is immediate:

  DSolve[% /. x - v t -> z, g, z]

  {{g -> Function[{z}, -((v^2*C[1])/(E^(((-1 + v^2)*z)/v)*(1 - v^2)*
      (-1 + v^2))) + C[2] + z*C[3]]}}

Cheers,
Paul

_______________________________________________________________________
Paul Abbott                                      Phone:  61 8 6488 2734
School of Physics, M013                            Fax: +61 8 6488 1014
The University of Western Australia         (CRICOS Provider No 00126G)    
AUSTRALIA                               http://physics.uwa.edu.au/~paul


  • Prev by Date: Re: Plotting
  • Next by Date: Re: NDSolve -- initial conditions
  • Previous by thread: Can Mathematica do Separation of Variables?
  • Next by thread: Changing Defaults