Re: GammaDistribution versus PoissonDistribution
- To: mathgroup at smc.vnet.net
- Subject: [mg78994] Re: [mg78977] GammaDistribution versus PoissonDistribution
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Sun, 15 Jul 2007 01:06:33 -0400 (EDT)
- Reply-to: hanlonr at cox.net
$Version
6.0 for Mac OS X x86 (32-bit) (June 19, 2007)
The Poisson distribution is discrete.
pDist = PoissonDistribution[m];
PDF[pDist, x]
m^x/(E^m*x!)
#[pDist] & /@ {Mean, StandardDeviation}
{m, Sqrt[m]}
Sum[PDF[pDist, x], {x, 0, Infinity}]
1
With[{m = RandomInteger[{2, 10}]},
ListPlot[Table[
{x, PDF[PoissonDistribution[m], x]},
{x, 0, Ceiling[m + 3 Sqrt[m]]}],
PlotStyle -> Red,
Filling -> Axis,
FillingStyle -> {{LightBlue, AbsoluteThickness[2]}}]]
The Gamma distribution is continuous
gDist = GammaDistribution[a, b];
PDF[gDist, x]
x^(a - 1)/(b^a*E^(x/b)*Gamma[a])
#[gDist] & /@ {Mean, StandardDeviation}
{a*b, Sqrt[a]*b}
Integrate[PDF[gDist, x], {x, 0, Infinity},
Assumptions -> {a > 0, b > 0}]
1
Plot[Evaluate[Table[Tooltip[
PDF[GammaDistribution[a, 1], x],
"a = " <> ToString[a]], {a, 1, 4}]],
{x, 0, 8},
PlotRange -> All]
Bob Hanlon
---- P_ter <peter_van_summeren at yahoo.co.uk> wrote:
> Hello,
> as far as I understand the GammaDistribution has two parameters: alfa and beta. With beta =1 one should get the PoissonDistribution with paramter alfa-1.
> I did, just to check:
> N[Table[{i, PDF[PoissonDistribution[12],i],
> PDF[GammaDistribution[13,1],i] },{i,0,30}]
> I got different values.
> Can anyone help me in what I do wrong?
> with friendly greetings,
> Peter
>