Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2007

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Animate with Slider Box Value

  • To: mathgroup at smc.vnet.net
  • Subject: [mg82498] Re: Animate with Slider Box Value
  • From: Albert <awnl at arcor.net>
  • Date: Mon, 22 Oct 2007 05:41:45 -0400 (EDT)
  • References: <ffcjrv$sfd$1@smc.vnet.net>

Hi,
> I would like to use the following example  Animate[Plot[Sin[a x]+Sin[b x],{x,0,10},PlotRange=AE2],{a,1,5},{b,1,5}] 


  But to include only a box with the currnet value of the slider, 
without the controls (e.g., Pause, etc.).

Also, I would like to include a more descriptive name for the slider. 
How can I this?  John C. Erb

Maybe this is what you want?

Animate[
  Plot[Sin[a x] + Sin[b x], {x, 0, 10}, PlotRange -> {-2, 2}],
  {{a, 1, "Parameter 1:"}, 1, 5},
  {{b, 1, "Parameter 2:"}, 1, 5},
  AnimatorElements -> "ProgressSlider"
  ]

If you want even more control, you probably can construct the Animate 
all by yourself, e.g. with something like:

Deploy[
  DynamicModule[{a = 1, b = 1},
   Panel[Column[{Row[{Animator[Dynamic[a], {1, 5},
         AppearanceElements -> None], "Parameter 1:", Spacer[5],
        InputField[Dynamic[a]]}],
      Row[{Animator[Dynamic[b], {1, 5}, AppearanceElements -> None],
        "Parameter 2:", Spacer[5], InputField[Dynamic[b]]}],
      Panel[
       Dynamic[
        Plot[Sin[a x] + Sin[b x], {x, 0, 10}, PlotRange -> {-2, 2}]],
       ImageSize -> 400
       ]
      }]
    ]]
  ]


hth,

albert


  • Prev by Date: Re: A riddle: Functions that return unevaluated when they cannot
  • Next by Date: Re: DSolving(?) for a given tangent
  • Previous by thread: Animate with Slider Box Value
  • Next by thread: how to control toolbar & pallete fonts