Re: Problem with inverse laplace transform (FIX)
- To: mathgroup at smc.vnet.net
- Subject: [mg81326] Re: Problem with inverse laplace transform (FIX)
- From: m.r at inbox.ru
- Date: Wed, 19 Sep 2007 05:31:47 -0400 (EDT)
- References: <fcb48a$fos$1@smc.vnet.net>
On Sep 13, 5:43 am, "Alexey Nikitin" <niki... at proc.ru> wrote:
> Hello,
>
> I am very sorry that my function wasn't in my mail at first time. I
> am a new user of Mathematica, and want to get the following inverse
> Laplace transform problem:
>
> I have 3 parameters h,m,n. Parameters m and n are integers. I tried
> to find inverse Laplace transform of function:
> InverseLaplaceTransform[-1/h - ((((-h+p)/(h+p))^(m-2n)) * (h+p)^2) /
> (h*(h-p)*p),p,x]
>
> *-*-*-*-*- Mathematica code *-*-*-*-*
>
> \!\(InverseLaplaceTransform[\(-\(1\/h\)\) - \(\((\(\(-h\) + p\)\/\(h +
> p\))\)\
> \^\(m - 2\ n\)\ \((h + p)\)\^2\)\/\(h\ \((h - p)\)\ p\), p, x]\)
>
> -*-*-*-*-*--*-*-*-*-*--*-*-*-*-*--*-*-*-*-*--*
>
> but mathematica can not give me an answer. Can it be solved by
> Mathematica?
>
> Thank you very much!
>
> Alexey.
You can express the result as a finite sum. For 2 n - m + 2 >= 0 we
have
In[1]:= HAp[p_] := -1/h - ((-h + p)/(h + p))^(m - 2 n)*
(h + p)^2/(h (h - p) p)
In[2]:= c[i_] := 1/(h p (p - h)^(2 n - m + 1))*
Binomial[2 n - m + 2, i] p^i h^(2 n - m + 2 - i)
In[3]:= FullSimplify[HAp[p] == -1/h + Sum[c[i], {i, 0, 2 n - m + 2}],
Element[{m, n}, Integers]]
Out[3]= True
In[4]:= Sum[InverseLaplaceTransform[c[2 n - m + 2 - i], p, x],
{i, 0, 2 n - m + 2}] //
Refine[#, Element[{m, n}, Integers]] /.
Binomial[n_, k_] :> Binomial[n, n - k]&
Out[4]= Sum[h^(-1 + i) x^(-1 + i) Binomial[2 - m + 2 n, i]
Hypergeometric1F1Regularized[1 - m + 2 n, i, h x], {i, 0, 2 - m + 2
n}]
In[5]:= Block[{n = 5, m = 2},
% == InverseLaplaceTransform[HAp[p], p, x] // FullSimplify]
Out[5]= True
In fact the transform of c[2 n - m + 2] is wrong because the image is
asymptotic to 1/h at infinity and the original contains a DiracDelta
term but it conveniently cancels out.
Maxim Rytin
m.r at inbox.ru