Mathematica 9 is now available
Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2008

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Viewpoint selector for Mac in 6.0?

  • To: mathgroup at smc.vnet.net
  • Subject: [mg86832] Re: Viewpoint selector for Mac in 6.0?
  • From: Szabolcs Horvát <szhorvat at gmail.com>
  • Date: Sun, 23 Mar 2008 00:59:54 -0500 (EST)
  • Organization: University of Bergen
  • References: <fs26q4$96$1@smc.vnet.net>

Ravi Balasubramanian wrote:
> Hello friends,
> 
> It appears that the viewpoint selector for 3D graphics is absent in 6.0 
> (Mac version).  Is there an alternate way to manually choose a view 
> (other than trying different viewpoints repeatedly)?  Suggestions 
> appreciated.

Here's a view point selector for you.  I am not sure that I do the 
copying right, so corrections are welcome.  Click the buttons to copy 
the values.

viewPointSelector[gr_Graphics3D] :=
  DynamicModule[
   {vp = ViewPoint /. Options[Graphics3D],
    vv = ViewVertical /. Options[Graphics3D],
    va = ViewAngle /. Options[Graphics3D]},
   Module[{copy},
    copy[expr_] :=
     NotebookPut[Notebook[{ToString[expr]}], ClipboardNotebook[]];
    Panel[Column[
      {Show[gr,
        ViewPoint -> Dynamic[vp], ViewVertical -> Dynamic[vv],
        ViewAngle -> Dynamic[va],
        SphericalRegion -> True, ImageSize -> 380],
       Grid[
        {{Button["ViewPoint", copy[vp]], Dynamic[vp]},
         {Button["ViewVertical", copy[vv]], Dynamic[vv]},
         {Button["ViewAngle", copy[va]], Dynamic[va]}},
        Alignment -> {Left, Baseline}]}
      ],
     ImageSize -> 400
     ]]]

(Side note: It would be nice if an automatically indented StandardForm 
expression would preserve the indentation levels exactly when copied.)


  • Prev by Date: Grabbing a value from a Dynamic Object
  • Next by Date: Re: ListPlot Joined/Filling bug?
  • Previous by thread: Re: Viewpoint selector for Mac in 6.0?
  • Next by thread: How can I make a fixed size arrowhead in 3D?