Re: Newcomer Question
- To: mathgroup at smc.vnet.net
- Subject: [mg102591] Re: [mg102586] Newcomer Question
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Sun, 16 Aug 2009 06:39:34 -0400 (EDT)
- Reply-to: hanlonr at cox.net
Use RegionFunction
Manipulate[ParametricPlot3D[
{Cos[u], Sin[u] + Cos[v], Sin[v]},
{u, 0, umax}, {v, -Pi, vmax},
RegionFunction -> Function[{x, y, z},
x < xmax && y > ymin && z < zmax],
PlotRange -> {{-1, 1}, {-2, 2}, {-1, 1}}],
{{umax, 2 Pi}, 0.01, 2 Pi, 0.01,
Appearance -> "Labeled"},
{{vmax, 2 Pi}, -Pi + 0.01, Pi, 0.01,
Appearance -> "Labeled"},
{{xmax, 1}, -1, 1, 0.02,
Appearance -> "Labeled"},
{{ymin, -2}, -2, 2, 0.04,
Appearance -> "Labeled"},
{{zmax, 1}, -1, 1, 0.02,
Appearance -> "Labeled"},
ControlType -> {Slider, VerticalSlider,
Slider, Slider, VerticalSlider},
ControlPlacement ->
{Top, Right, Top, Bottom, Right}]
Bob Hanlon
---- VICTOR <victor.herasme at gmail.com> wrote:
=============
Hi,
i have to analyze a huge amount of data. In this page:
http://www.wolfram.com/products/mathematica/newin6/content/DynamicInteractivity/UseAllStandardFormsOfControls.html
i found an example that would be very useful to my work. Does anyone
have any idea on how to create this ? Specifically what i need is the
plane that cuts the graphic and shows the values at a specific
position, i.e. a plane parallel to the XY that i can place at any
position of the Z axis. Any suggestions appreciated. Thanks,
Victor