Mathematica 9 is now available
Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2009

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: if only on parameter of 2D is to be shown in 3D

  • To: mathgroup at smc.vnet.net
  • Subject: [mg102861] Re: [mg102843] if only on parameter of 2D is to be shown in 3D
  • From: Bob Hanlon <hanlonr at cox.net>
  • Date: Mon, 31 Aug 2009 06:34:09 -0400 (EDT)
  • Reply-to: hanlonr at cox.net

This adds a fill option and tooltips. However, the tooltips are hard to activate except at the edges.


Manipulate[Show[{
   If[Fill, ParametricPlot3D[
     {u + v^2, u^2 - v, v*u},
     {u, -2, 2}, {v, -2, 2},
     Mesh -> False], {}],
   Table[
    ParametricPlot3D[
     Tooltip[{u + v^2, u^2 - v, v*u},
      "u = " <> ToString[u]],
     {v, -2, 2},
     PlotStyle ->
      Directive[AbsoluteThickness[tu], Blue]],
    {u, -2, 2, du}],
   Table[
    ParametricPlot3D[
     Tooltip[{u + v^2, u^2 - v, v*u}, 
      "v = " <> ToString[v]],
     {u, -2, 2},
     PlotStyle ->
      Directive[AbsoluteThickness[tv], Darker[Red]]],
    {v, -2, 2, dv}]},
  PlotRange -> {{-2, 6}, {-2, 6}, {-4, 4}}],
 {Fill, {True, False}},
 {{du, 0.25}, 0.05, 1, 0.05,
  Appearance -> "Labeled"},
 {{tu, Medium, "Thickness"}, {Medium, Large}},
 {{dv, 0.25}, 0.05, 1, 0.05,
  Appearance -> "Labeled"},
 {{tv, Medium, "Thickness"}, {Medium, Large}}]


Bob Hanlon

---- Bob Hanlon <hanlonr at cox.net> wrote: 

=============

Not sure that I know what you want. This may help

Manipulate[
 Show[{
   Table[
    ParametricPlot3D[
     {u + v^2, u^2 - v, v*u}, {v, -2, 2},
     PlotStyle ->
      Directive[AbsoluteThickness[tu], Blue]],
    {u, -2, 2, du}],
   Table[
    ParametricPlot3D[
     {u + v^2, u^2 - v, v*u}, {u, -2, 2},
     PlotStyle ->
      Directive[AbsoluteThickness[tv], Red]],
    {v, -2, 2, dv}]},
  PlotRange ->
   {{-2, 6}, {-2, 6}, {-4, 4}}],
 {{du, 0.125}, 0.05, 0.40, 0.05,
  Appearance -> "Labeled"},
 {{tu, Medium, "Thickness"}, {Medium, Large}},
 {{dv, 0.125}, 0.05, 0.40, 0.05,
  Appearance -> "Labeled"},
 {{tv, Medium, "Thickness"}, {Medium, Large}}]


Bob Hanlon

---- Narasimham <mathma18 at hotmail.com> wrote: 

=============
Is it possible to see only a one parameter family ( either u or v ) of
lines drawn in
ParametricPlot3D [ {u + v^2, u^2 - v, v* u }, {u, -2, 2}, {v, -2, 2}]
with either shaded and not shaded options?

TIA
Naarsimham




  • Prev by Date: Re: Re: Eigenvalues broken?
  • Next by Date: Re: Re: Viewing packages in mathematica
  • Previous by thread: Re: if only on parameter of 2D is to be shown in 3D
  • Next by thread: If and ReplaceAll