MathGroup Archive 2009

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Can't reproduce a solution found in a paper using

  • To: mathgroup at smc.vnet.net
  • Subject: [mg102859] Re: [mg102845] Can't reproduce a solution found in a paper using
  • From: Bob Hanlon <hanlonr at cox.net>
  • Date: Mon, 31 Aug 2009 06:33:46 -0400 (EDT)
  • Reply-to: hanlonr at cox.net

The expression being integrated is

expr1 = J*((\[Rho]*J)/(2*t))*(x*(a - x) - 
          8*a^2/Pi^3*
            Sum[((Cosh[((2*m + 1)*Pi*y)/a]/
                      Cosh[((2*m + 1)*Pi*b)/a])*
                   Sin[((2*m + 1)*Pi*x)/a])/(2*m + 1)^3, 
              {m, 0, Infinity}]);

Expand this out

expr2 = expr1 // Expand

-((4*a^2*J^2*\[Rho]*
           Sum[(Sech[(Pi*b*(2*m + 1))/a]*
                  Sin[(Pi*(2*m + 1)*x)/a]*
                  Cosh[(Pi*(2*m + 1)*y)/a])/
               (2*m + 1)^3, {m, 0, Infinity}])/
        (Pi^3*t)) + (a*J^2*x*\[Rho])/(2*t) - 
   (J^2*x^2*\[Rho])/(2*t)

The individual terms of the sum are

expr3 = Last[expr2] /.
  (Sum[z_, {__}] :> z)

-((4*a^2*J^2*\[Rho]*Sech[(Pi*b*(2*m + 1))/
             a]*Sin[(Pi*(2*m + 1)*x)/a]*
         Cosh[(Pi*(2*m + 1)*y)/a])/
      (Pi^3*(2*m + 1)^3*t))

Integrating these individual terms of the sum

expr4 = Simplify[
  Integrate[expr3, {y, 0, b}, {x, 0, a}],
  Element[m, Integers]]

-((8*a^4*J^2*\[Rho]*Tanh[(Pi*b*(2*m + 1))/
             a])/((2*Pi*m + Pi)^5*t))

The other terms of expr2 are

expr5 = Most[expr2]

(a*J^2*x*\[Rho])/(2*t) - (J^2*x^2*\[Rho])/
     (2*t)

Integrating these

expr6 = Integrate[expr5, {y, 0, b}, {x, 0, a}]

(a^3*b*J^2*\[Rho])/(12*t)

soln = (expr6 + Sum[expr4, {m, 0, Infinity}])

Sum[-((8*a^4*J^2*\[Rho]*Tanh[
               (Pi*b*(2*m + 1))/a])/
          ((2*Pi*m + Pi)^5*t)), 
     {m, 0, Infinity}] + (a^3*b*J^2*\[Rho])/
     (12*t)

Which is the result provided in the paper


Bob Hanlon

---- Neelsonn <neelsonn at gmail.com> wrote: 

=============
Guys,

This is what I want to solve:

J \!\(
\*SubsuperscriptBox[\(\[Integral]\), \(0\), \(b\)]\(
\*SubsuperscriptBox[\(\[Integral]\), \(0\), \(a\)]
\(\*FractionBox[\(\[Rho]\ J\), \(2\ t\)]\)[x \((a - x)\) -
FractionBox[\(8
\*SuperscriptBox[\(a\), \(2\)]\),
SuperscriptBox[\(\[Pi]\), \(3\)]] \(
\*UnderoverscriptBox[\(\[Sum]\), \(m = 0\), \(\[Infinity]\)]
\*SuperscriptBox[\((2  m + 1)\), \(-3\)]\ *\
\*FractionBox[\(Cosh[
\*FractionBox[\(\((2  m + 1)\) \[Pi]\ y\), \(a\)]]\), \(Cosh[
\*FractionBox[\(\((2  m + 1)\) \[Pi]\ b\), \(a\)]]\)]\ *\ Sin[
\*FractionBox[\(\((2  m +
              1)\) \[Pi]\ x\), \(a\)]]\)] \[DifferentialD]x \
\[DifferentialD]y\)\)


...and this is the solution that I found in a publication:

(\[Rho] J^2)/(2 t)*[(a^3 b)/6 - (16 a^4)/\[Pi]^5 \!\(
\*UnderoverscriptBox[\(\[Sum]\), \(m = 0\), \(\[Infinity]\)]\(
SuperscriptBox[\((2  m + 1)\), \(-5\)] Tanh[
\*FractionBox[\(\((2  m + 1)\) \[Pi]\ b\), \(a\)]]\)\)]

I am simply not able to reproduce that with Mathematica. The obvious
questions is: why? If someone would be willing to have a look at the
the paper I could sent it over. I may say that the paper dated back
from the 70's and at that time Mathematica wasn't available (people
were smart at that time!!!! lol)

Thanks again,
N


--

Bob Hanlon



  • Prev by Date: Re: Re: Viewing packages in mathematica
  • Next by Date: Re: ClearAll ?? or what
  • Previous by thread: Mathematica plot not matching up to excel plot tia sal22