Re: Correction to "Fundamental Theorem of Calculus and
- To: mathgroup at smc.vnet.net
- Subject: [mg100770] Re: [mg100727] Correction to "Fundamental Theorem of Calculus and
- From: Bob Hanlon <hanlonr at cox.net>
- Date: Sat, 13 Jun 2009 06:04:43 -0400 (EDT)
- Reply-to: hanlonr at cox.net
g[x_] := Integrate[E^(-t^2), {t, 0, x}]
D[g[x], x] === g'[x]
False
Trace[D[g[x], x]]
{{HoldForm[g[x]], HoldForm[Integrate[E^(-t^2),
{t, 0, x}]], HoldForm[(1/2)*Sqrt[Pi]*
Erf[x]]}, HoldForm[
D[(1/2)*Sqrt[Pi]*Erf[x], x]],
HoldForm[E^(-x^2)]}
Trace[g'[x]]
{{HoldForm[Derivative[1][g]],
{HoldForm[g[#1]], HoldForm[
Integrate[E^(-t^2), {t, 0, #1}]],
HoldForm[(1/2)*Sqrt[Pi]*Erf[3]]},
HoldForm[0 & ]}, HoldForm[(0 & )[x]],
HoldForm[0]}
This appears to be the problem
Integrate[Exp[-t^2], {t, 0, #1}]
(1/2)*Sqrt[Pi]*Erf[3]
g[x_] := Evaluate[Integrate[E^(-t^2), {t, 0, x}]]
D[g[x], x] === g'[x]
True
g[x_] = Integrate[E^(-t^2), {t, 0, x}];
D[g[x], x] === g'[x]
True
Bob Hanlon
---- L Wapner <lwapner2 at gmail.com> wrote:
=============
Hi Bob:
Mine works as well using the "D" notation for derivative. But why will it
not work using the "prime" notation? See below.
In[1]:= g[x_] := Integrate[E^(-t^2), {t, 0, x}]
In[2]:= g'[x]
Out[2]= 0
In[3]:= D[g[x], x]
Out[3]= E^(-x^2)
Thanks,
Len
On Thu, Jun 11, 2009 at 8:18 PM, Bob Hanlon <hanlonr at cox.net> wrote:
> Works in my version.
>
> $Version
>
> 7.0 for Mac OS X x86 (64-bit) (February 19, 2009)
>
> f[x_] := Integrate[Sin[t^2], {t, 0, x}]
>
> D[f[x], x]
>
> Sin[x^2]
>
> g[x_] := Integrate[Exp[-t^2], {t, 0, x}]
>
> D[g[x], x]
>
> E^(-x^2)
>
>
> Bob Hanlon
>
> ---- Len <lwapner2 at gmail.com> wrote:
>
> =============
> Greetings:
>
> I define a function (using f[x_]:=) as the definite integral (from 0
> to x) of sin(t^2). When I differentiate using Mathematica I get the
> correct answer of sin(x^2).
>
> But when I define a function (using g[x_]:=) as the definite integral
> (from 0 to x) of e^(-t^2) and differentiate, I get the incorrect
> answer of 0. (The correct answer is e^(-x^2).)
>
> Why the inconsistency?
>
> Oddly, if I define the function g above using "=" instead of ":=", all
> works well.
>
> Can someone explain the odd behavior?
>
> Thanks,
>
> Len
>