Re: Beginning syntax problems
- To: mathgroup at smc.vnet.net
- Subject: [mg104561] Re: Beginning syntax problems
- From: dh <dh at metrohm.com>
- Date: Wed, 4 Nov 2009 01:32:51 -0500 (EST)
- References: <hcono6$1iq$1@smc.vnet.net>
Hi Michael,
"Dynamic" can not be given in an argument of a function that is executed
in the kernel. Therefore, you must take it out of "Table".
Further, the dummy variable "m" and "b" are not know outside of
"Manipulate". Therefore, either you save them in an global variable or
you place the x-y table inside "Manipulate" (how I have done).
I also used "PaddedForm" to prevent the picture constantly changing its
width.
Manipulate[
Column[{
Plot[m x + b, {x, -5, 5}, PlotRange -> {{-5, 5}, {-5, 5}}],
Dynamic[
PaddedForm[
TableForm[Transpose@Table[{x, m*x + b}, {x, -5, 5}],
TableHeadings -> {{"x", "y"}}], 2]]
}],
{m, 2, -2, -.5}, {b, 2, -2, -.5} ]
Daniel
Michael Greene wrote:
> I'm coaching a middle school Mathcounts program and am attempting to use
> Mathematica to illustrate some simple ideas. I've created the following
> script to illustrate slope and intercept.
>
> Grid[{{Manipulate[
> Graphics[{{Dotted, Line[{{1, 0}, {1, m + b}}]}, {Dotted,
> Line[{{0, m + b}, {1, m + b}}]},
> Annotation[Line[t = {Table[{x, m*x + b}, {x, -5, 5}]}], "Line",
> "Mouse"]
> }, Axes -> True, AxesLabel -> {x, "y=mx+b"},
> PlotRange -> {{-5, 5}, {-5, 5}}], {b, 2, -2, -.5,
> ControlType -> None},
> Row[{"m",
> Manipulator[Dynamic[m], {2, -2, -.5}, Appearance -> "Labeled",
> ImageSize -> Small], "b",
> Manipulator[Dynamic[b], {2, -2, -.5}, Appearance -> "Labeled",
> ImageSize -> Small]}]],
> Grid[{"x", "y",
> Grid[Table[{x, Dynamic[m]*x + 2}, {x, -5, 5}],
> Frame -> {All, False}]}]}}]
>
> My problems with the script are twofold. First, I can't get the table on the
> right side to dynamically update its values as I adjust the slope and
> intercept. The second problem is I'm having a heck of a time placing labels
> on top of their respective columns in the same table. I'm just trying to put
> an x and a y above the two table columns but can't figure out the correct
> Mathematica syntax to make it happen.
>
> Can anyone correct the above script so it exhibits those two features?
>
> Thanks,
>
> Michael green
>
>