MathGroup Archive 2011

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Manipulate, how to slowdown animation

  • To: mathgroup at smc.vnet.net
  • Subject: [mg117988] Re: Manipulate, how to slowdown animation
  • From: Alexei Boulbitch <alexei.boulbitch at iee.lu>
  • Date: Thu, 7 Apr 2011 08:06:18 -0400 (EDT)

Juan,

the most straightforward way is something like this:

Export[NotebookDirectory[]<>  "singraph.avi",
  Manipulate[
   Plot[Sin[a x], {x, 0, 2 \[Pi]},
    PlotRange ->  {{0, 2 \[Pi]}, {-1, 1}}], {a, 1, 2}]]

After executing this you get a file singraph.avi in the same directory, in which you have your actual notebook.
But do not forget to first save your actual notebook somewhere, since without this
NotebookDirectory[] will have no sense.

If, however, you need to create a movie out of a rather complex graphics so that each movement in Mathematica takes time,
you may want to do it another way around. To give an idea check this:

(* This is a function depending upon a parameter v *)
z[x_, y_, v_] :=
   3*(1 - v^2)*Exp[-0.15*x*v] (1 - 0.62*y/Power[x^2 + y^2, (4)^-1])*
    Exp[-0.15*Sqrt[x^2 + y^2]];

(* This is a graphics depending upon the parameter v *)

image[v_] := Plot3D[z[x, y, v], {x, -10, 4}, {y, -4, 4},

    (* These options below are only specifications to make the Plot more beautiful and could be easily omitted  *)
    PlotStyle ->  {Opacity[0.9]},
    PlotRange ->  {{-10, 4}, {-4, 4}, {0, 5}}, AspectRatio ->  0.8,
    ColorFunction ->  "Rainbow", Mesh ->  None, Boxed ->  False,
    Ticks ->  None, AxesLabel ->  {"x", "y", "\[Eta]"},
    AxesStyle ->  Directive[Large],
    ViewPoint ->  {15*Sin[1.4]*Cos[-2.5 Pi/4],
      15 Sin[1.4]*Sin[-2.5 Pi/4], 15*Cos[1.4]}, ImageSize ->  500,
    PlotLabel ->
     Style["\[Eta](x-vt,y): a 3D plot", FontFamily ->  "Times",
      FontSize ->  20, FontWeight ->  "Plain"]
    (* End of the Plot  specifications  *)

                   ];


(*  This is the table of images  *)
movie = Table[image[v], {v, 0, 1, 0.025}];

(* Here it is exported as a movie  *)
Export[NotebookDirectory[]<>  "movie.avi", movie, "FrameRate" ->  3]

Again you get the file movie.avi in the directory of your notebook after execution.
You may want to play with the FrameRate parameter in the last operator.





On Apr 5, 5:42 am, =A9er=FDch Jakub<Ser... at panska.cz>  wrote:
>  Thanks, that's exactly what I was looking for.
>
>  Jakub

BTW, how do you export from manipulate to any movie format?

Cheers,

Juan

-- 
Alexei Boulbitch, Dr. habil.
Senior Scientist
Material Development

IEE S.A.
ZAE Weiergewan
11, rue Edmond Reuter
L-5326 CONTERN
Luxembourg

Tel: +352 2454 2566
Fax: +352 2454 3566
Mobile: +49 (0) 151 52 40 66 44

e-mail: alexei.boulbitch at iee.lu

www.iee.lu

--

This e-mail may contain trade secrets or privileged, undisclosed or
otherwise confidential information. If you are not the intended
recipient and have received this e-mail in error, you are hereby
notified that any review, copying or distribution of it is strictly
prohibited. Please inform us immediately and destroy the original
transmittal from your system. Thank you for your co-operation.



  • Prev by Date: Re: package construction
  • Next by Date: CDF browser plugin and Wolfram library archive
  • Previous by thread: Re: Manipulate, how to slowdown animation
  • Next by thread: Re: Manipulate, how to slowdown animation