MathGroup Archive 2011

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: 3D of combine plot

  • To: mathgroup at smc.vnet.net
  • Subject: [mg116470] Re: 3D of combine plot
  • From: Bob Hanlon <hanlonr at cox.net>
  • Date: Wed, 16 Feb 2011 04:36:44 -0500 (EST)

data = Table[{t, 5 k + t}, {k, {0, 2, 3, 4}}, {t, 20}];

ListLinePlot[data]

to3D[list_, val_] := Insert[#, val, 2] & /@ list

Graphics3D[Riffle[Take[ColorData[1, "ColorList"], 4],
  Line /@
   to3D @@@ Thread[{data, {0, 2, 3, 4}}]],
 Axes -> True,
 BoxRatios -> {GoldenRatio, 1, 1}]


Bob Hanlon

---- Gazi Habiba Akter <gazihabiba02 at gmail.com> wrote: 

=============
Hi Bob,
Thanks for your reply.
But i think my case is little bit different. I got plots after doing inverse
first fourier transform, f(t) versus t and these are listlineplot.
Now i need combine 3d plots of f(t) with respect to time(t) for several
values of k.
could you please give me suggestion for my case.

Thanks,
Gazi

On Tue, Feb 15, 2011 at 9:48 AM, Bob Hanlon <hanlonr at cox.net> wrote:

>
> k = {0, 2, 3, 4};
>
> Plot[Evaluate[
>  Table[
>   Tooltip[2 Sin[x + p] + x, p],
>   {p, k}]],
>  {x, 0, 15}]
>
> ParametricPlot3D[Evaluate[
>  Table[
>   {x, p, 2 Sin[x + p] + x},
>   {p, k}]],
>  {x, 0, 15},
>  BoxRatios -> {GoldenRatio, 1, 1}]
>
>
> Bob Hanlon
>
> ---- Gazi Habiba Akter <gazihabiba02 at gmail.com> wrote:
>
> =============
> Hi,
> I have  4 plots for different value of k (0,2,3,4). I combined all
> plots by Show. But i want the combine plot in 3D (in simple form).How
> can i get this.i use Mathematica 7.
>
> Thanks,
> Gazi
>
>

--

Bob Hanlon



  • Prev by Date: Re: To put name to columns
  • Next by Date: Re: NInegrate Bug
  • Previous by thread: Re: 3D of combine plot
  • Next by thread: To put name to columns