Mathematica 9 is now available
Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2012

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Partial derivative function definitions

  • To: mathgroup at smc.vnet.net
  • Subject: [mg127552] Re: Partial derivative function definitions
  • From: Bob Hanlon <hanlonr357 at gmail.com>
  • Date: Fri, 3 Aug 2012 04:18:20 -0400 (EDT)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • Delivered-to: l-mathgroup@wolfram.com
  • Delivered-to: mathgroup-newout@smc.vnet.net
  • Delivered-to: mathgroup-newsend@smc.vnet.net
  • References: <20120802085042.189D36864@smc.vnet.net>

You want the derivatives carried out while x and y are symbolic rather
than numeric, use Set rather than SetDelayed.

XFunction[x_, y_] = Sin[x] Sin[y];
YFunction[x_, y_] = Cos[x] Cos[y];
dXFunctiondx[x_, y_] = D[XFunction[x, y], x];
dXFunctiondy[x_, y_] = D[XFunction[x, y], y];
dYFunctiondx[x_, y_] = D[YFunction[x, y], x];
dYFunctiondy[x_, y_] = D[YFunction[x, y], y];

Partition[DensityPlot[#[x, y],
     {x, -2 Pi, 2 Pi}, {y, -2 Pi, 2 Pi}] & /@
   {XFunction, YFunction,
    dXFunctiondx, dYFunctiondx,
    dXFunctiondy, dYFunctiondy}, 2] //
 Grid


Bob Hanlon


On Thu, Aug 2, 2012 at 4:50 AM, Mat' G. <ellocomateo at free.fr> wrote:
> Hello,
> Can someone please explain me why the following partial derivative
> function definitions do not work? I get errors like:
> General::ivar: -6.28229 is not a valid variable. >>
> General::ivar: -5.38469 is not a valid variable. >>
> General::ivar: -4.48709 is not a valid variable. >>
> General::stop: Further output of General::ivar will be suppressed during
> this calculation. >>
>
> Thanks for helping!
> Mat
>
>
>
>
> XFunction[x_, y_] := Sin[x] Sin[y];
> YFunction[x_, y_] := Cos[x] Cos[y];
> dXFunctiondx[x_, y_] := D[XFunction[x, y], x];
> dXFunctiondy[x_, y_] := D[XFunction[x, y], y];
> dYFunctiondx[x_, y_] := D[YFunction[x, y], x];
> dYFunctiondy[x_, y_] := D[YFunction[x, y], y];
>
> Grid[{
>    {
>     DensityPlot[
>      XFunction[x, y], {x, -2 \[Pi], 2 \[Pi]}, {y, -2 \[Pi], 2 \[Pi]}]
>     , DensityPlot[
>      YFunction[x, y], {x, -2 \[Pi], 2 \[Pi]}, {y, -2 \[Pi], 2 \[Pi]}]
>     }
>    , {
>     DensityPlot[
>      dXFunctiondx[x, y], {x, -2 \[Pi], 2 \[Pi]}, {y, -2 \[Pi], 2 \[Pi]}]
>     , DensityPlot[
>      dYFunctiondx[x, y], {x, -2 \[Pi], 2 \[Pi]}, {y, -2 \[Pi], 2 \[Pi]}]
>     }
>    , {
>     DensityPlot[
>      dXFunctiondy[x, y], {x, -2 \[Pi], 2 \[Pi]}, {y, -2 \[Pi], 2 \[Pi]}]
>     , DensityPlot[
>      dYFunctiondy[x, y], {x, -2 \[Pi], 2 \[Pi]}, {y, -2 \[Pi], 2 \[Pi]}]
>     }
>    }]
>



  • Prev by Date: Re: Lining Up Checkboxes in Manipulate
  • Next by Date: Evaluation of a whole notebook from another one
  • Previous by thread: Partial derivative function definitions
  • Next by thread: Re: Partial derivative function definitions