Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2012

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: coloring individual hexagons in a grid...

  • To: mathgroup at smc.vnet.net
  • Subject: [mg127914] Re: coloring individual hexagons in a grid...
  • From: Bob Hanlon <hanlonr357 at gmail.com>
  • Date: Fri, 31 Aug 2012 04:01:26 -0400 (EDT)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • Delivered-to: l-mathgroup@wolfram.com
  • Delivered-to: mathgroup-newout@smc.vnet.net
  • Delivered-to: mathgroup-newsend@smc.vnet.net
  • References: <20120828085302.9525568C1@smc.vnet.net>

Then make Hexagon a Polygon rather than a Line.

Hexagon[x_] :=
 Polygon[x + # & /@ (Through[{Cos, Sin}[Pi #/3]] & /@ Range[0, 6])]

HexagonalGrid[nbrRows_, nbrColumns_, colorFunction_: Null] :=
 Module[{i, j},
  Table[{If[colorFunction === Null, Lighter[Gray, .9], colorFunction[i, j]],
    Hexagon[{3/2 j, Sqrt[3] i + Mod[j, 2] Sqrt[3]/2}]}, {i, nbrRows}, {j,
    nbrColumns}]]

With[{k = 3},
 Show[Graphics[{EdgeForm[Thick], HexagonalGrid[k, k]}],
  AspectRatio -> Automatic]]

With[{k = 3},
 Show[Graphics[{EdgeForm[Thick],
    HexagonalGrid[k, k, Hue[Rescale[#1 + #2, {2, 2 k}]] &]},
   AspectRatio -> Automatic]]]

On Thu, Aug 30, 2012 at 12:34 PM, Richard Palmer <rhpalmer at gmail.com> wrote:
> Thanks Bob,  However, I am trying to color the interior of the hexagons, not
> the edges.
>
>
> On Wed, Aug 29, 2012 at 11:26 PM, Bob Hanlon <hanlonr357 at gmail.com> wrote:
>>
>> Hexagon[x_] :=
>>  Line[x + # & /@
>>    (Through[{Cos, Sin}[Pi #/3]] & /@
>>      Range[0, 6])]
>>
>> HexagonalGrid[nbrRows_, nbrColumns_,
>>   colorFunction_: Null] :=
>>  Module[{i, j},
>>   Table[{
>>     If[colorFunction === Null,
>>      Black,
>>      colorFunction[i, j]],
>>     Hexagon[
>>      {3/2 j, Sqrt[3] i + Mod[j, 2] Sqrt[3]/2}]}, {i, nbrRows}, {j,
>>     nbrColumns}]]
>>
>> With[{k = 3},
>>  Show[Graphics[
>>    HexagonalGrid[k, k]],
>>   AspectRatio -> Automatic]]
>>
>> With[{k = 3},
>>  Show[Graphics[
>>    HexagonalGrid[k, k, Hue[
>>       Rescale[#1 + #2, {2, 2 k}]] &],
>>    AspectRatio -> Automatic]]]
>
>
>
>
> --
> Richard Palmer
>
> Home                            941 412 8828
> Cell                               508 982-7266
>
>



  • Prev by Date: Re: Creating animated 3d graphic in Mathematica for export
  • Next by Date: Re: Assumptions does not work in Eliminate?
  • Previous by thread: Re: coloring individual hexagons in a grid...
  • Next by thread: How to specify x-axis in List when using ListPlot