Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: Plotting a simple line at a weibull ProbabilityScalePlot

• To: mathgroup at smc.vnet.net
• Subject: [mg125323] Re: Plotting a simple line at a weibull ProbabilityScalePlot
• From: Bob Hanlon <hanlonr357 at gmail.com>
• Date: Tue, 6 Mar 2012 06:00:54 -0500 (EST)
• Delivered-to: l-mathgroup@mail-archive0.wolfram.com
• References: <201203050741.CAA29900@smc.vnet.net>

The coordinates for the Line need to be scaled the same way as the
data was scaled. From the More Information section of the Help page
for ProbabilityScalePlot:  {Log[x], Log[-Log[1 - y]]}

data1 = RandomVariate[WeibullDistribution[1, 1], 100];
data2 = RandomVariate[WeibullDistribution[1, 10], 100];
data3 = RandomVariate[WeibullDistribution[1, 2], 100];

ProbabilityScalePlot[
 {data1, data2, data3},
 "Weibull",
 PlotRange -> Automatic,
 GridLines -> Automatic,
 GridLinesStyle -> "Classic",
 FrameLabel -> {
   {Style["Ausfallwahrscheinlichkeit F(t) in %",
     Italic, FontSize -> 12], ""},
   {Style["Lebensdauer",
     Italic, FontSize -> 12], ""}},
 Frame -> True,
 Epilog -> {Red,
   Map[{Log[#[[1]]], Log[-Log[1 - #[[2]]]]} &,
    Line[{{0.001, .6321}, {100, .6321}}], {2}]}]


Bob Hanlon


On Mon, Mar 5, 2012 at 2:41 AM, Martin Palatini
<martin.palatini at googlemail.com> wrote:
> Hello,
>
> I got a big problem with my ProbabilityScalePlot. I want to plot a
> simple, horizontal line in my diagramm. This diagramm shows a weibull
> plot. In this weibull plot are shown three different weibull
> distribution functions.
>
> At the value of 63.21% on the y-axis, i want to plot this simple
> horizontal line. This line symbolize the characteristic lifetime of a
> component. I don't get it.
>
> Please help me, i need this plot for my master thesis.
>
> The code for the plot is called:
>
> data1 = RandomVariate[WeibullDistribution[1, 1], 100];
> data2 = RandomVariate[WeibullDistribution[1, 10], 100];
> data3 = RandomVariate[WeibullDistribution[1, 2], 100];
>
> ProbabilityScalePlot[{data1, data2, data3}, "Weibull",
>  PlotRange -> Automatic, GridLines -> Automatic,
>  GridLinesStyle -> "Classic",
>  FrameLabel -> {{Style["Ausfallwahrscheinlichkeit F(t) in %", Italic,
>     FontSize -> 12],
>    ""}, {Style["Lebensdauer", Italic, FontSize -> 12], ""}},
>  Frame -> True]
>
> P.S. My english isn't so good, but i hope you understand me.

• References:
  • Plotting a simple line at a weibull ProbabilityScalePlot
    • From: Martin Palatini <martin.palatini@googlemail.com>