Re: Conformal Mapping
- To: mathgroup at smc.vnet.net
- Subject: [mg128564] Re: Conformal Mapping
- From: Andrzej Kozlowski <akozlowski at gmail.com>
- Date: Sun, 4 Nov 2012 00:44:42 -0400 (EDT)
- Delivered-to: l-mathgroup@mail-archive0.wolfram.com
- Delivered-to: l-mathgroup@wolfram.com
- Delivered-to: mathgroup-newout@smc.vnet.net
- Delivered-to: mathgroup-newsend@smc.vnet.net
- References: <20121101071908.8E0F6684E@smc.vnet.net> <20121102044326.4FACA6849@smc.vnet.net>
On 2 Nov 2012, at 05:43, Murray Eisenberg <murray at math.umass.edu> wrote:
>
> On Nov 1, 2012, at 3:19 AM, MaxJ <maxjasper at shaw.ca> wrote:
>>
>> I need help finding a Mobius transform such that the region:
>>
>> |z-i| < sqrt(2)
>> &&
>> |z+i| < sqrt(2)
>>
>> in z-plane be mapped conformally into a unit circle in w-plane.
>>
>> Any help is appreciated very much.
>>
>
>
> I assume you really did mean "and" rather than "or" in describing the region.
>
> This seems more like a mathematics question than a Mathematica question.
>
> Mathematica can help peripherally. The two circles bounding the region obviously intersect at complex points z = -1 and z = 1. They intersect the imaginary axis at the points found from:
>
> ptBelow=z/.First@Solve[{Abs[z-I]==Sqrt[2],Re[z]==0,Im[z]<0}, z];
> ptAbove=z/.First@Solve[{Abs[z+I]==Sqrt[2],Re[z]==0,Im[z]>0}, z];
> pts={ptBelow,ptAbove}
> {I*(1 - Sqrt[2]), I*(-1 + Sqrt[2])}
>
> And you may easy plot the region by using David Park's "Presentations" application, which allows you to express things directly in terms of complex numbers:
>
> << Presentations`
>
> Draw2D[{
> Opacity[0.6],
> ComplexRegionDraw[Abs[z - I] < Sqrt[2] && Abs[z + I] < Sqrt[2], {z, -2 - 2 I, 2 + 2 I},
> BoundaryStyle -> Directive[Thick, Dashed]],
> PointSize[Large], ComplexPoint /@ pts
> },
> Axes -> True]
>
> As to the mathematics: the region is "lens-shaped". Consider what the Moebius transformation you seek does to the boundary -- surely maps it onto the unit circle. Consider the inverse of that transformation. Now apply the theorem that the image of a circle under any Moebius transformation is a circle (in the extended complex plane or, equivalently, on the Riemann sphere).
>
>
> ---
> Murray Eisenberg murray at math.umass.edu
> Mathematics & Statistics Dept.
> Lederle Graduate Research Tower phone 413 549-1020 (H)
> University of Massachusetts 413 545-2838 (W)
> 710 North Pleasant Street fax 413 545-1801
> Amherst, MA 01003-9305
>
>
You most certainly do not need any external packages (you never really need them, don't believe when they tell you otherwise). To get a quick picture of your region just use:
RegionPlot[
Abs[x + I y - I] < Sqrt[2] && Abs[x + I y + I] < Sqrt[2], {x, -2,
2}, {y, -2, 2}]
You can make it much more fancy if you want, but for most purposes this is enough. It's both quicker and much cheaper than the suggested method.
Murray's mathematical solution is, of course, fine although he did not give you the explicit mapping. Actually, you can automate almost the entire process by using the cross ratio. First, define the cross ratio:
crossRatio[z_, q_, r_, s_] := (z - q) (r - s)/((z - s) (r - q))
Next, we take three points on the boundary of the lens and map them onto three points on the boundary of the unit circle. Since Murray has already shown how to find the first three points, we can take:
points1 = {-1, 1, (-1 + Sqrt[2]) I};
For the three points on the unit circle we can take
points2 = {I, -I, 1};
The order is important. Also, since the Moebius transformation does not map the lens onto the unit disk (only into), you can find more than one mapping that wil accomplish the task. Anyway, here is how we find a mapping:
ff[z_] = w /.
Solve[crossRatio[z, Sequence @@ points1] ==
crossRatio[w, Sequence @@ points2], w][[1]] // Simplify;
Lets check if our ff does really what we want, in other words, maps points1 onto points2:
ff/@points1//Simplify
{I,-I,1}
So we have a Moebius transformation (or a linear fractional transformation) which maps three points on the boundary of the lens onto three points on the unit circle. It is easy to check that the interior of the lens goes into the interior of the circle. To see the image of the interior we need to find the inverse Moebius transform:
gg[w_]=z/.Solve[ff[z]==w,z][[1]];
Check again that this works fine on the boundary points:
gg/@points1//Simplify
{-1,1,I (Sqrt[2]-1)}
We can now again use RegionPlot to see the image of the lens:
RegionPlot[
Abs[gg[x + I y ] - I] < Sqrt[2] &&
Abs[gg[x + I y ] + I] < Sqrt[2], {x, -2, 2}, {y, -2, 2}]
You can also check that the image of the half-disk under the inverse Moebius transform gg is indeed your lens:
RegionPlot[
Abs[ff[x + I y]] < 1 && Re[ff[x + I y]] > 0, {x, -2, 2}, {y, -2, 2}]
Andrzej Kozlowski
- Follow-Ups:
- Re: Conformal Mapping
- From: Murray Eisenberg <murray@math.umass.edu>
- Re: Conformal Mapping
- References:
- Conformal Mapping
- From: MaxJ <maxjasper@shaw.ca>
- Re: Conformal Mapping
- From: Murray Eisenberg <murray@math.umass.edu>
- Conformal Mapping