Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2012

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: FindInstance question? Any ideas to solve this equality.

  • To: mathgroup at smc.vnet.net
  • Subject: [mg128568] Re: FindInstance question? Any ideas to solve this equality.
  • From: Dana DeLouis <dana01 at me.com>
  • Date: Sun, 4 Nov 2012 20:12:12 -0500 (EST)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • Delivered-to: l-mathgroup@wolfram.com
  • Delivered-to: mathgroup-newout@smc.vnet.net
  • Delivered-to: mathgroup-newsend@smc.vnet.net

Hi.   I might hold off inserting machine numbers until later.  Here's one idea:

data={
radiusV1->145.98630072715727,
radiusV2->95.62128455180272,
slopeV1Deg->9.462322208025617,
slopeV2Deg->18.43494882292201
};

Work with your equation.  (I'll use t1 & t2)

(360*radiusV1)/(slopeV1Deg+360*timeV1x)==(360*radiusV2)/(slopeV2Deg+360*timeV2x)&&(360*(radiusV1*2))/(slopeV1Deg*2+360*(timeV1x*2))==(360*(radiusV2*2))/(slopeV2Deg*2+360*(timeV2x*2))
 /. {timeV1x->t1,timeV2x->t2}   ;

I find this easier to work with this:

equ = %//FullSimplify

radiusV1/(slopeV1Deg+360 t1)==radiusV2/(slopeV2Deg+360 t2)

Let's solve for t1:

FullSimplify[Solve[equ,t1]] [[1,1,-1]]

(-radiusV2 slopeV1Deg+radiusV1 (slopeV2Deg+360 t2))/(360 radiusV2)


Now, use your data:

%/.data  // FullSimplify
0.051896 +1.52671 t2

So, t1 is equal to the above.  If we subtract them, the equation is equal to zero.

t1-%
-0.051896+t1-1.52671 t2

f equals the above equation that is equal to zero.

f=%
-0.051896+t1-1.52671 t2

There really is no integer solution within a large range:

Minimize[{Abs[f],0<t1<10000000000,0<t2<10000000000},{t1,t2},Integers]

{0.578609,{t1->1,t2->1}}

As a side note:

If you Rationalized the machine numbers, you would have:

Rationalize[f,0]
-(3592760/69229991)+t1-(118038537 t2)/77315450

Try to use integers for t1 & t2

%*77315450  //FullSimplify
-(277775856142000/69229991)+77315450 t1-118038537 t2

Rearranged, you would have:

77315450 t1-118038537 t2 == 277775856142000 / 69229991

As you can see, there are no integer solutions for t1 & t2 that would give a rational number.

Even if you wanted to round the rational number, the solution is still not reasonable:

277775856142000 / 69229991 // Floor
4012363

Minimize[Abs[77315450 t1-118038537 t2-4012363],{t1,t2},Integers]
{0,{t1->471271145234969,t2->308683431630951}}

Minimize[Abs[77315450 t1-118038537 t2-4012364],{t1,t2},Integers]
{0,{t1->471271262689732,t2->308683508564028}}


Just throwing this out.  You may find the function FrobeniusSolve and related functions interesting reading.   However, it doesn't help here for this problem.

= = = = = = = = = =
HTH  :>)
Dana DeLouis
Mac & Mathematica 8
= = = = = = = = = =





On Friday, November 2, 2012 11:54:28 PM UTC-4, Lea Rebanks wrote:
> FindInstance question:
> Hi All,
> I have evaluated the following equality with FindInstance function and
> 
> there appears to be no results.
> 
> Please could someone review the following equality to see if my result is
> 
> TRUE or Is it possible to find one or more Integer results to this equality.
> Clear[radiusV1]
> 
> radiusV1 = 145.98630072715727;
> Clear[radiusV2]
> radiusV2 = 95.62128455180272;
> Clear[slopeV1Deg]
> slopeV1Deg = 9.462322208025617;
> Clear[slopeV2Deg]
> 
> slopeV2Deg = 18.43494882292201;
> 
> Clear[timeV1x]
> 
> Clear[timeV2x]
> 
> FindInstance[(360*radiusV1)/(slopeV1Deg + 360*timeV1x) ==
> 
        (360*radiusV2)/(slopeV2Deg + 360*timeV2x) &&
> 
>      (360*(radiusV1*2))/(slopeV1Deg*2 + 360*(timeV1x*2)) ==
> 
>        (360*(radiusV2*2))/(slopeV2Deg*2 + 360*(timeV2x*2)) &&
> 
>      timeV1x > 0 && timeV2x > 0, {timeV1x, timeV2x},
> 
>    Integers, 2]
> 
> {}
> 
> 
> Any help or advice gratefully received.
> 
> Best regards,
> 
> Lea=85




  • Prev by Date: A nice and customized legend within Manipulate
  • Next by Date: Re: Conformal Mapping
  • Previous by thread: Re: FindInstance question? Any ideas to solve this equality.
  • Next by thread: Group Elements: Changing permutation group cycles to more readable form