Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2013

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Output display by slide

  • To: mathgroup at smc.vnet.net
  • Subject: [mg131777] Re: Output display by slide
  • From: Bob Hanlon <hanlonr357 at gmail.com>
  • Date: Wed, 2 Oct 2013 05:55:16 -0400 (EDT)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • Delivered-to: l-mathgroup@wolfram.com
  • Delivered-to: mathgroup-outx@smc.vnet.net
  • Delivered-to: mathgroup-newsendx@smc.vnet.net
  • References: <20131001102101.9E7E46A5E@smc.vnet.net>

Manipulate[
 Module[
  {a = 3, c = 2,
   v1, v2, v3, x1, y1, x2, y2,
   XF, YF, CG, Triang},
  v1 = Circle[{0, 0}, {.03, .03}];
  v2 = Circle[{a, 0}, {.03, .03}];
  v3 = Circle[{b, c}, {.03, .03}];
  x1 = a; y1 = 0; x2 = b; y2 = c;
  {XF, YF} = {x1 + x2, y1 + y2}/3;
  CG = Disk[{XF, YF}, {.05, .05}];
  Triang =
   Line[{{0, 0}, {a, 0}, {b, c}, {0, 0},
     {XF, YF}, {a, 0}, {XF, YF}, {b, c},
     {XF, YF}, {0, 0}}];
  Graphics[{v1, v2, v3, Triang, CG},
   GridLines -> Automatic,
   Frame -> True,
   PlotRange -> {{-0.1, 4.1}, Automatic},
   PlotLabel ->
    Style["Centre of Gravity", 16]]],
 {{b, 2.5}, 0, 4, 0.1,
  Appearance -> "Labeled"}]



Bob Hanlon




On Tue, Oct 1, 2013 at 6:21 AM, Narasimham <mathma18 at gmail.com> wrote:

> a=3; b=2.5;  c=2 ;
> (*  Given triangle vertices are {(0,0),(x1,y1),(x2,y2)} = {
> (0,0),(a,0),(b,c) } to find CG  *)
>
> v1=Graphics[Circle[{0,0},{.03,.03}]];v2=Graphics[Circle[{a,0},{.03,.03}]];v3=Graphics[Circle[{b,c},{.03,.03}]];
> x1=a;y1=0;x2=b;y2=c; {XF,YF}={x1+x2, y1+y2}/3;
> CG=Graphics[Disk[{XF,YF},{.05,.05} ]];
> Triang=Graphics[Line[{{0,0},{a,0},{b,c},{0,0},{XF,YF},{a,0},{XF,YF},{b,c},{XF,YF},{0,0}}]
> ] ;
> bb=Show[{v1,v2,v3,Triang,CG},GridLines->Automatic,Axes-> True
> ,AspectRatio-> Automatic, PlotLabel-> "Centre of Gravity"]
>
> How  to vary b value in a SlideView or Manipulate, say between 0 to 4,
> (along horizontal line y =2) to display Centre of Gravity  like it is in
> GSP or in Java mode ?
>
> TIA,
> Narasimham
>
>




  • Prev by Date: Re: Output display by slide
  • Next by Date: Re: ProgressIndicator in ParallelTable problem, redux
  • Previous by thread: Re: Output display by slide
  • Next by thread: Re: Output display by slide