Re: help me plz
- To: mathgroup at smc.vnet.net
- Subject: [mg32164] Re: [mg32149] help me plz
- From: Reza Malek-Madani <research at usna.edu>
- Date: Mon, 31 Dec 2001 02:24:22 -0500 (EST)
- Sender: owner-wri-mathgroup at wolfram.com
Here is a numerical solution to your BVP but with infinity replaced with
100 (you can make this value larger if you wish). The approximation uses
the shooting method, FindRoot and NDSolve.
Reza.
**********************************
$TextStyle = {FontFamily -> "Times", FontSize -> 14};
mylabel[x_] := StyleForm[TraditionalForm[x]];
F[b_] := Module[{sol, result},
sol = NDSolve[{y'[x] == yp[x],
yp'[x] == ypp[x],
ypp'[x] == -1/2 yp[x]ypp[x],
y[0] == 0, yp[0] == 0, ypp[0] == b}, {y, yp, ypp},
{x, 0, 100}, MaxSteps -> 1000000];
result = First[Evaluate[yp[x] /. sol /. x -> 100]]];
shoot = FindRoot[F[b] - 1, {b, 0.1, 0.2}];
sol = NDSolve[{y'[x] == yp[x],
yp'[x] == ypp[x],
ypp'[x] == -1/2 yp[x]ypp[x],
y[0] == 0, yp[0] == 0, ypp[0] == b /. shoot}, {y, yp, ypp},
{x, 0, 100}, MaxSteps -> 1000000];
newy[x_] = y[x] /. sol;
Plot[newy[x], {x, 0, 100}, PlotLabel -> "Graph of y"];
graph = Plot[yp[x] /. sol, {x, 0, 100},
PlotLabel -> mylabel["Graph of yprime"], PlotRange -> All];
-------------------------------------------------------------------------
Reza Malek-Madani Director of Research
Research Office, MS 10m Phone: 410-293-2504 (FAX -2507)
589 McNair Road DSN: 281-2504
U.S. Naval Academy Nimitz Room 17 in ERC
Annapolis MD 21402-5031 Email: research at usna.edu
--------------------------------------------------------------------------
On Sat, 29 Dec 2001, Samer wrote:
>
> i want to solve this equation
>
> y"*y'+2y"'=0
>
> y(0)=0
> y'(0)=0
> y'(infini)=1
>