       Re: Corrupt graphics output

• To: mathgroup at smc.vnet.net
• Subject: [mg90697] Re: Corrupt graphics output
• From: "David Park" <djmpark at comcast.net>
• Date: Sat, 19 Jul 2008 04:52:08 -0400 (EDT)
• References: <g5pj0s\$qbg\$1@smc.vnet.net>

```If you are using Version 6 you don't need a lot of PlotPoints. You can
control things better using MaxRecursion. The following gives a fairly
decent representation:

Plot3D[Abs[Gamma[x + I y]], {x, -5.5, 5}, {y, -2, 2},
PlotPoints -> {20, 5},
MaxRecursion -> 4,
PlotRange -> {0, 10},
BoxRatios -> {10.5, 4, 8},
AxesLabel -> {Re[z], Im[z], Abs[Gamma[z]]}]

Each of the poles should have infinite height but instead they have smaller
height for the more negative poles. One method to supplement the graphic is
to add a table of the residues obtained by integrating around each pole.

poles = {0, -1, -2, -3, -4, -5};
Table[{z0,
With[{\[CapitalDelta] = .05},
NIntegrate[
Gamma[z], {z, z0 - \[CapitalDelta] - I \[CapitalDelta],
z0 + \[CapitalDelta] - I \[CapitalDelta],
z0 + \[CapitalDelta] + I \[CapitalDelta],
z0 - \[CapitalDelta] + I \[CapitalDelta],
z0 - \[CapitalDelta] - I \[CapitalDelta]}] // Abs]}, {z0,
poles}] // TableForm

0   6.28319
-1  6.28319
-2  3.14159
-3  1.0472
-4  0.261799
-5  0.0523599

--
David Park
djmpark at comcast.net
http://home.comcast.net/~djmpark/

"Paul M" <paul at somewhere.com> wrote in message
news:g5pj0s\$qbg\$1 at smc.vnet.net...
> Hello,
>
> I was playing around with Mathematica the other day and was attempting
> to graph the modulus of the complex-valued gamma function.  When I use
> a PlotPoints value of 120 the graph looks fine.  However, the
> following command yields a corrupt graph (PlotPoints value of 150).
>
> Plot3D[Abs[Gamma[x + I y]], {x, -5, 5}, {y, -5, 5},
> PlotPoints -> {150, 150}, PlotRange -> {0, 10},
> BoxRatios -> {1, 1, 0.8}, AxesLabel -> {x, I y, Abs[Gamma[z]]}]
>
> Anyone know the reason for this and possible solutions?
>
> Thank you,
> Paul
>

```

• Prev by Date: Re: changing the NumberForm of Automatic Plot Ticks
• Next by Date: Re: Labeled Plot not a Plot?
• Previous by thread: Re: Corrupt graphics output
• Next by thread: changing the NumberForm of Automatic Plot Ticks