MathGroup Archive 2010

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Help Improving this integral calculation / solution

  • To: mathgroup at smc.vnet.net
  • Subject: [mg108103] Re: [mg108044] Help Improving this integral calculation / solution
  • From: "David Park" <djmpark at comcast.net>
  • Date: Mon, 8 Mar 2010 06:15:17 -0500 (EST)
  • References: <14141119.1267954710922.JavaMail.root@n11>

This goes much better if you use exact values:

d = 7/10; 
v = 1/20; 
a = 1/10; 
nk = (a + (1 - a) k v t)/(d + a + (1 - a) k v t) // Simplify 
 
(20  + 9 k t)/(160 + 9 k t) 

pg[k_] = Exp[1 - k]; 
gavg = Integrate[k pg[k], {k, 1, \[Infinity]}];(*This is just 2*) 
result = 1/gavg Integrate[nk k pg[k], {k, 1, \[Infinity]}, 
   Assumptions -> 0 < t < 1]; 
f[t_] = result 

(9 t (-70 + 9 t) - 
 11200 E^(1 + 160/(9 t)) ExpIntegralEi[-1 - 160/(9 t)])/(81 t^2) 

Plot[f[t] - t, {t, 0, 0.2},
 PlotRange -> Automatic] 

FindRoot[f[t] == t, {t, .15}]  
{t -> 0.142045} 

I tried solving the integral with a, d and v as parameters, and accepting
the conditions but that did not work.


David Park
djmpark at comcast.net
http://home.comcast.net/~djmpark/  


From: DOD [mailto:dcodea at gmail.com] 


I have an integral I need to calculate, with one variable left
symbolic, and then use the result to find a numerical solution to an
equation, and the result of the integration is not giving me what I
need:
------
d = .7;
v = .05;
a = .1;
nk = (a + (1 - a) k v t)/(d + a + (1 - a) k v t);

pg[k_] = Exp[1-k];
gavg = Integrate[k pg[k], {k, 1, \[Infinity]}]; (* This is just 2 *)
result =   1/gavg Integrate[nk k pg[k], {k, 1, \[Infinity]},
Assumptions -> 0 < t < 1];
test = FullSimplify[result]

FindRoot[test == t, {t, .1}]

-----
This code always gives up and stays at the initial guess.  So, I look
at the result of the integration, "result" (or it's simplified
version, test2) and calculated it for various values of t, and it is
always zero.
----
test/.t->{.1,.2,.3}
----
Output:{3.36999*10^66, 0., 0.}
-----

So that's a problem.  If I set t=.3, say, and the beginning, and
calculate the integral, I get 0.160047, which is clearly not zero.
-----
d = .7;
v = .05;
a = .1;
t = .3;
nk = (a + (1 - a) k v t)/(d + a + (1 - a) k v t);

pg[k_] = Exp[1 - k];
gavg =Integrate[k pg[k], {k, 1, \[Infinity]}];(*This is just 2*)

result = 1/gavg Integrate[nk k pg[k], {k, 1, \[Infinity]}]
----
Output=0.160047
-----

 So there is a problem in the Integrate step.  So I want to find a
point where the output of that integral (result), as a function of t,
satisfies result=t.  Is there anyway to do this using built-in
functions?





  • Prev by Date: Re: Help Improving this integral calculation / solution
  • Next by Date: Re: Possible bug in Table and/or lists (Mathematica v.7)
  • Previous by thread: Re: Help Improving this integral calculation / solution
  • Next by thread: Conjugate of symbolic expressions