Re: How to find the eigenvalues/eigenfunctions of a
- To: mathgroup at smc.vnet.net
- Subject: [mg113399] Re: How to find the eigenvalues/eigenfunctions of a
- From: Mark McClure <mcmcclur at unca.edu>
- Date: Wed, 27 Oct 2010 05:15:30 -0400 (EDT)
On Tue, Oct 26, 2010 at 5:34 AM, Nasser M. Abbasi <nma at 12000.org> wrote:
> Given Lu==u''[x], with boundary conditions u'[0]==0,u'[1]==0, need to
> find the eigenvalues and eigenfunctions of L.
You could do something like a shooting method, with the parameter
lambda as the input to your shooting function. Algebraically, this
would look like so:
Clear[u, lambda];
sol = DSolve[{u''[x] + (lambda^2) u[x] == 0,
u[0] == 1, u'[0] == 0}, u[x], x];
u[x_] = u[x] /. First[sol]
Now the question is, for which values of the parameter lambda is u'[1]==0?
Reduce[u'[1] == 0, lambda]
You can also do it numerically.
shot[lambda_?NumericQ] := Module[{u},
u[x_] = u[x] /. First[NDSolve[
{u''[x] + (lambda^2) u[x] == 0, u[0] == 1, u'[0] == 0},
u[x], {x, 0, 1}]];
u'[1]];
FindRoot[shot[lambda] == 0, {lambda, 3}]
Once you have an eigenvalue, an eigenfunction is easy to find.
Mark McClure
Mark McClure