Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: OutputResponse issue

• To: mathgroup at smc.vnet.net
• Subject: [mg128897] Re: OutputResponse issue
• From: Bob Hanlon <hanlonr357 at gmail.com>
• Date: Mon, 3 Dec 2012 04:03:07 -0500 (EST)
• Delivered-to: l-mathgroup@mail-archive0.wolfram.com
• Delivered-to: l-mathgroup@wolfram.com
• Delivered-to: mathgroup-newout@smc.vnet.net
• Delivered-to: mathgroup-newsend@smc.vnet.net
• References: <20121202095840.E142D6877@smc.vnet.net>

outResponse[k_: 0.53, t_] =
  OutputResponse[
    TransferFunctionModel[
     k/(k + 2 s + 3 s^2 + s^3), s],
    UnitStep[t], t] // FullSimplify;

Plot[
 Evaluate[
  Table[
   Tooltip[
    outResponse[k, t],
    "k = " <> ToString[k]],
   {k, 0.53 {1, 2, 3}}]],
 {t, 0, 10},
 Frame -> True, Axes -> False,
 FrameLabel -> (Style[#, Bold, 14] & /@
    {"t",
     "Output  Response\n"})]

Manipulate[outResponse[k_, t_] =
  OutputResponse[
    TransferFunctionModel[
     k/(k + 2 s + 3 s^2 + s^3), s],
    UnitStep[t], t] // FullSimplify;
 Plot[
  Chop[outResponse[k, t]],
  {t, 0, 10},
  Frame -> True, Axes -> False,
  PlotRange -> {0, 1.5},
  FrameLabel -> (Style[#, Bold, 14] & /@
     {"t",
      "Output  Response\n"})],
 {{k, 0.53}, .05, 2.5, .01,
  Appearance -> "Labeled"}]


Bob Hanlon


On Sun, Dec 2, 2012 at 4:58 AM, Eduardo M. A. M. Mendes
<emammendes at gmail.com> wrote:
>
> Hello
>
> Can anyone help me with the following issue?
>
> Plot[Chop at OutputResponse[TransferFunctionModel[0.53/(0.53+2 s+3 s s+s s s),s],UnitStep[t],t],{t,0,10}]
>
> which returns
>
> OutputResponse::nsymb :  "0.0002042857142857143` must be a symbol. \
> =91=99=98ButtonBox["",
> Appearance->{Automatic, None},
> BaseStyle->"Link",
> ButtonData:>"paclet:ref/OutputResponse",
> ButtonNote->"OutputResponse::nsymb"]"
>
> and several other msgs.
>
> I have tried a different approach
>
> restfmf[t_,k_]:=OutputResponse[TransferFunctionModel[(k 1.06)/(k 1.06+2 s+3 s s+s s s),s],UnitStep[t],t];
>
> Plot[Chop@Evaluate@restfmf[t, 0.5], {t, 0, 10}]
>
> but got the same error messages
>
> What am I missing here?
>
> Many thanks
>
> Ed
>
>
>

• Follow-Ups:
  • Re: OutputResponse issue
    • From: "Eduardo M. A. M. Mendes" <emammendes@gmail.com>
  • Re: OutputResponse issue
    • From: "Eduardo M. A. M. Mendes" <emammendes@gmail.com>

• References:
  • OutputResponse issue
    • From: Eduardo M. A. M. Mendes <emammendes@gmail.com>