Services & ResourcesWolfram ForumsMathGroup Archive

[Date Index] [Thread Index] [Author Index]

Re: Average the same elements of the list

• To: mathgroup at smc.vnet.net
• Subject: [mg130888] Re: Average the same elements of the list
• From: Bob Hanlon <hanlonr357 at gmail.com>
• Date: Thu, 23 May 2013 04:10:37 -0400 (EDT)
• Delivered-to: l-mathgroup@mail-archive0.wolfram.com
• Delivered-to: l-mathgroup@wolfram.com
• Delivered-to: mathgroup-outx@smc.vnet.net
• Delivered-to: mathgroup-newsendx@smc.vnet.net
• References: <20130522061810.01F4F6A31@smc.vnet.net>

data = {{{a1, b1, c1}, d1}, {{a2, b2, c2}, d2},
   {{a1, b1, c1}, d3}, {{a2, b2, c2}, d4},
   {{a1, b1, c1}, d5}, {{a3, b3, c3}, d7}};


For v7 and later


sol = Plus @@ #/Length[#] & /@
  GatherBy[data, First]


{{{a1, b1, c1}, (1/3)*(d1 + d3 + d5)},
   {{a2, b2, c2}, (d2 + d4)/2}, {{a3, b3, c3}, d7}}


or (probably faster for longer lists)


sol == ({#[[1, 1]], Mean[#[[All, 2]]]} & /@
   GatherBy[data, First])


True


For v3 or later


sol == (Plus @@ #/Length[#] & /@
   Split[data // Sort, #1[[1]] == #2[[1]] &])


True



Bob Hanlon




On Wed, May 22, 2013 at 2:18 AM, BBabic <bipsich101 at gmail.com> wrote:

> Hello,
> I have list which is something like
> data={
> {{a1,b1,c1},d1},{{a2,b2,c2},d2}}
> I would like to get new list which gets average of the second elements if
> the first elements in the sublists are all the same.
> Namely if a1=a2,b1=b2,c1=c2
> new list would look like
> datanew={{a1,b1,c1},Mean[{d1,d2}]
> Is there an elegant way to do this ?
> Thanks!
>
>

• References:
  • Average the same elements of the list
    • From: BBabic <bipsich101@gmail.com>