Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2001

[Date Index] [Thread Index] [Author Index]

Search the Archive

RE: Inverse Laplace output format?

  • To: mathgroup at smc.vnet.net
  • Subject: [mg28795] RE: [mg28769] Inverse Laplace output format?
  • From: "David Park" <djmp at earthlink.net>
  • Date: Sun, 13 May 2001 03:28:44 -0400 (EDT)
  • Sender: owner-wri-mathgroup at wolfram.com

Jose,

I love these "surgery on expressions" problems! Here is one path to the
solution.

In[102]:=
f = (11*s^2 + 172*s + 700)/((s + 2)*(s^2 + 12*s + 100))
InverseLaplaceTransform[f, s, t]
ComplexExpand[%]
Collect[%, E^(-6*t)]
% /. a_*Cos[x_] + b_*Sin[x_] :> Sqrt[a^2 + b^2]*Cos[x - ArcTan[b/a]]
% /. ArcTan[x_] :> N[ArcTan[x]/Pi]*180*HoldForm[Degree]

Out[102]=
(700 + 172*s + 11*s^2)/((2 + s)*(100 + 12*s + s^2))

Out[103]=
(3 + 4*I)*E^((-6 - 8*I)*t) + (3 - 4*I)*E^((-6 + 8*I)*t) + 5/E^(2*t)

Out[104]=
5/E^(2*t) + (6*Cos[8*t])/E^(6*t) + (8*Sin[8*t])/E^(6*t)

Out[105]=
5/E^(2*t) + (6*Cos[8*t] + 8*Sin[8*t])/E^(6*t)

Out[106]=
5/E^(2*t) + (10*Cos[8*t - ArcTan[4/3]])/E^(6*t)

Out[107]=
5/E^(2*t) + (10*Cos[8*t - 53.13010235415597*HoldForm[Degree]])/E^(6*t)

The last expression looks much better in StandardForm. ArcTan[4/3] is the
exact expression for 53.13 Degree and you should usually skip the last step.

David Park
djmp at earthlink.net
http://home.earthlink.net/~djmp/


> From: Jose Lopez Jr. [mailto:chilibean2in at netzero.net]
To: mathgroup at smc.vnet.net
>
> I have the following inverse Laplace -
>
> f = (11s^2 + 172s + 700)/((s + 2)(s^2 + 12s + 100))
> InverseLaplaceTransform[f, s, t]
>
> but the answer is in exponential form.
>
> I understand the ExpToTrig command but I want to get the
> answer in "cos theta in degree" form -
>
> 5Exp[-2t] + 10Exp[-6t]cos(8t - 53.13°)
>
> How do I do that because when I use the ExpToTrig I get
>
> (3 - 4 \[ImaginaryI]) Cosh[(6 + 8 \[ImaginaryI]) t] - (3 - 4
> \[ImaginaryI])
> Sinh[(6 + 8 \[ImaginaryI]) t]
>
> and don't know what to do to get it to my "cos theta in degree" form.
>



  • Prev by Date: Re: column * row ??
  • Next by Date: don't understand #
  • Previous by thread: Re: Inverse Laplace output format?
  • Next by thread: Exponential Equations