Re: two integrals
- To: mathgroup at smc.vnet.net
- Subject: [mg79121] Re: [mg79079] two integrals
- From: Daniel Lichtblau <danl at wolfram.com>
- Date: Thu, 19 Jul 2007 03:28:56 -0400 (EDT)
- References: <200707180653.CAA04305@smc.vnet.net>
dimitris wrote:
> Any ideas for closed form expressions for the
> following integrals?
>
> In[71]:=
> Integrate[ArcTan[(1 - z^2)/z^3]*(1/(z + p)), {z, 0, 1}]
>
> In[73]:=
> Integrate[ArcTan[(1 - z^2)/z^3]*(1/(z - p)), {z, 0, 1}, PrincipalValue
> -> True]
>
> [Parameter p takes values in the range (0,1) so
> the second integral should be interpreted as a Cauchy
> principal value integral]
>
> Thanks, in advance, for your time and effort.
>
> D.A.
>
That first one can be done as follows. Note that this will take
considerable time and computing resources (at least if done on my
machine). The idea is to expand the ArcTan as a series at z=1 and
integrate termwise. Due to the nature of the actual series I found it
expedient to split into the first few terms followed by the tail.
firstpart = Normal[Series[ArcTan[(1-z^2)/z^3],
{z,1,3}, Assumptions->0<z<1]];
tailterm = Simplify[SeriesCoefficient[ArcTan[(1-z^2)/z^3],
{z,1,n}], Assumptions->n>3];
tail = Sum[tailterm*(z-1)^n, {n,4,Infinity}];
firstpartintegrated = Integrate[firstpart*(1/(z+p)),
{z,0,1}, Assumptions->0<p<1];
tailintegrated = Integrate[tail*(1/(z+p)),
{z,0,1}, Assumptions->0<p<1]
integral = firstpartintegrated+tailintegrated;
The result is well to the south of ugly.
In[47]:= LeafCount[integral]
Out[47]= 795684
But it passes some sanity checks.
In[48]:= integral /. p->.3
-14
Out[48]= 1.91292 + 3.58739 10 I
In[49]:= NIntegrate[ArcTan[(1-z^2)/z^3]*(1/(z+.3)), {z,0,1}]
Out[49]= 1.91292
In[50]:= FreeQ[integral,Series|Sum|Integrate]
Out[50]= True
Possibly stronger simplification of intermediate results would lead to a
better form? I don't know.
Daniel Lichtblau
Wolfram Research
- References:
- two integrals
- From: dimitris <dimmechan@yahoo.com>
- two integrals