Re: Plot contour regions over a globe

• To: mathgroup at smc.vnet.net
• Subject: [mg101141] Re: Plot contour regions over a globe
• From: Jens-Peer Kuska <kuska at informatik.uni-leipzig.de>
• Date: Thu, 25 Jun 2009 07:12:01 -0400 (EDT)
• Organization: Uni Leipzig
• References: <h1svbm\$mi0\$1@smc.vnet.net>
• Reply-to: kuska at informatik.uni-leipzig.de

```Hi,

what is so complicated on

plt = ContourPlot[
Re[SphericalHarmonicY[6, 3, th, phi]], {th, 0, Pi}, {phi, 0, 2 Pi},
ContourShading -> False, ContourStyle -> {Red, Green, Blue, Yellow}]

Graphics3D[
{Cases[plt, _GraphicsComplex, Infinity] /.
GraphicsComplex[pnts_, more___] :>
GraphicsComplex[
Function[{th, phi},
1.01*{Cos[phi]*Sin[th], Sin[phi]*Sin[th], Cos[th]}] @@@ pnts,
more], Sphere[{0, 0, 0}, 1]}
]

And

plt = ContourPlot[
Re[SphericalHarmonicY[6, 3, th, phi]], {th, 0, Pi}, {phi, 0, 2 Pi}]

Graphics3D[
{Cases[plt, _GraphicsComplex, Infinity] /.
GraphicsComplex[pnts_, more___] :>
GraphicsComplex[
Function[{th, phi},
1.01*{Cos[phi]*Sin[th], Sin[phi]*Sin[th], Cos[th]}] @@@ pnts,
more]}
]

are also working.

Regards
Jens

michaell1 wrote:
> Hello,
>
> I'm in need of some advice and any help would be appreciated.
>
> I'm trying to use Mathematica to plot a representation of coverage areas on top of a representation of a globe. But I would like to have countries outlined on the sphere. I tried the new Geo plot toolbox and to show all the countries uses a enormous amount of resources. This is not quite the solution I am hoping for.
>
> The contour regions plotted over the globe will be inputted as latitude and longitude which brings me to another missing piece of Mathematica. There doesn't seem to be a tool to plot coordinates in 3D. I believe these were all new features in v7 so I hope for many more features to come in the future.
>
> Thanks in advance!
>
> -Mike
>

```

• Prev by Date: Re: Ansatz?
• Next by Date: Re: Possible bug in Mathematica 7 using ColorFunction
• Previous by thread: Re: Plot contour regions over a globe
• Next by thread: *slowing down* a Mathematica process (Dynamic/Refresh question)