MathGroup Archive 2011

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: Contour ColorFunction in a ParametricPlot

  • To: mathgroup at smc.vnet.net
  • Subject: [mg120122] Re: Contour ColorFunction in a ParametricPlot
  • From: Heike Gramberg <heike.gramberg at gmail.com>
  • Date: Sat, 9 Jul 2011 07:30:49 -0400 (EDT)
  • References: <201107080851.EAA28634@smc.vnet.net>

On 8 Jul 2011, at 09:51, Bob Hanlon wrote:

>
> contours = 6;
> ParametricPlot3D[
> {Cos[p] Sin[t], Sin[p] Sin[t], Cos[t]},
> {p, 0, 2 Pi}, {t, 0, Pi},
> PlotPoints -> 200,
> Mesh -> None,
> ColorFunction -> Function[{x, y, z, p, t},
>   Hue[Round[Sin[6 p] Sin[6 t], 1/contours]]],
> ColorFunctionScaling -> True]
>
>
> Bob Hanlon
>

Another way to create this effect would be to use MeshFunctions in combination
with MeshShading:

With[{meshn = 10},
 ParametricPlot3D[{Cos[\[Phi]] Sin[\[Theta]],
   Sin[\[Phi]] Sin[\[Theta]], Cos[\[Theta]]}, {\[Phi], 0,
   2 \[Pi]}, {\[Theta], 0, \[Pi]}, PlotPoints -> 100,
  MeshFunctions -> {Function[{x, y, z, \[Phi], \[Theta]},
     Sin[6  Rescale[\[Phi], {0, 2 Pi}]] Sin[
       6 Rescale[\[Theta], {0, Pi}]]]},
  Mesh -> meshn, MeshShading -> Table[Hue[i], {i, 0, 1, 1/meshn}],
  MeshStyle -> None, Lighting -> "Neutral"]]

Heike.


> ---- "Blandeau M.N." <mnb1f10 at soton.ac.uk> wrote:
>
> =============
> Hello,
> I looked for this specific question in the archive and I did not find.
>
> I want to create a contour (ie. not smooth) ColorFunction over a parametricplot.
>
> For example:
> ParametricPlot3D[ {Cos[ \[Phi]] Sin[\[Theta]],
>  Sin[\[Phi]] Sin[\[Theta]], Cos[\[Theta]]}, {\[Phi], 0,
>  2 \[Pi]}, {\[Theta], 0, \[Pi]}, PlotPoints -> 100, Mesh -> None,
> ColorFunction ->
>  Function[{x, y, z, \[Phi], \[Theta]},
>   Hue[Sin[6 \[Phi]] Sin[6 \[Theta]]]], ColorFunctionScaling -> True]
>
> Here the colorfunction is smooth, what directive should I add to obtain a contour of the colour and to manage the number of contours ?
>
> Thanks in advance.
>
> Mathias Blandeau
>
>
> From: Blandeau M.N.
> Sent: 06 July 2011 14:35
> To: 'mathgroup at smc.vnet.net'
> Subject: subscription to mathgroup mailing list
>
> Hi,
> I would like to be added to the mathgroup mailing list, I am using Mathematica for my PhD and I have several questions to ask.
> Thank you in advance
>
> Mathias Blandeau
>
>



  • Prev by Date: Calculating General Tensor Product of Gradients
  • Next by Date: Re: How to write a "proper" math document
  • Previous by thread: Re: Contour ColorFunction in a ParametricPlot
  • Next by thread: Re: Contour ColorFunction in a ParametricPlot