Re: Vectors
- To: mathgroup at smc.vnet.net
- Subject: [mg124264] Re: Vectors
- From: Tomas Garza <tgarza10 at msn.com>
- Date: Sat, 14 Jan 2012 17:15:57 -0500 (EST)
- Delivered-to: l-mathgroup@mail-archive0.wolfram.com
- References: <201201140757.CAA01372@smc.vnet.net>
You have to develop some familiarity with 3D graphics. I would do the following: first, try to guess the region to visualize the plane. It seems that the region where all three coordinates x, y, z are between -5 and 5 is appropriate. Then produce the plane plot in 3D, and call it "plane":
plane = ContourPlot3D[ 6 x - 2 y + z == 11, {x, -5, 5}, {y, -5, 5}, {z, -5, 5}, Mesh -> None]
Now find the point in the plane which lies on the straight line. To this end, solve the system with all four equations for both the plane and the straight line; i.e., find the values x, y, z, h using Solve:
Solve[{6 x - 2 y + z == 11, x - 1 == (y + 1)/2, x - 1 ==
(z - 3)/h, (y + 1)/2 == (z - 3)/h}, {x, y, z, h}] // Quiet
(I wrap the request with Quiet to prevent unnecessary messages in the output). I obtain the result
{{y -> -3 + 2 x, z -> 5 - 2 x, h -> -2}, {x -> 1, y -> -1, z -> 3}}
Note that the solutions are given in terms of rules (please check the meaning of "Rule" in the online Help). This is disconcerting at first, but it is the only way to do it: a straight "=" cannot be used, as this means "Set" in Mathematica. Then you have two sets of solutions; notice that the second one is equal to the first one when h equals -2, and corresponds to a point on the plane. This point can be visualized evaluating the following:
point = Graphics3D[{PointSize[0.02], Point[{1, -1, 3}]}];
where I use a large point size to produce a very visible object. I use a semicolon at the end to prevent it from showing, as I don't need to see the point by itself. Now you can see the plane and the point (only half of it, since the other half is behind the plane) together by evaluating
Show[plane, point]
(be careful not to use capital letters in these names, so as not to conflict with Mathematica's own symbols). You obtain a 3D graph with the plane and the point on it. As you move your mouse over the figure you'll notice a 3D cursor, a pair of curved arrows. Press and keep pressed the left button to rotate the figure in all directions. In particular you may see the point in full when you have the plane parallel to your line of sight. Finally, solve the straight line equations with h equal to -2 and you get
Solve[{x - 1 == (y + 1)/2, x - 1 == -(z - 3)/2, (y + 1)/2 == -(z - 3)/2}, {x, y, z}] // Quiet
{{y -> -3 + 2 x, z -> 5 - 2 x}}
You may now plot a line from x = -5 to x = 5, say "line" (substitute these values for x in the last result):
line = Graphics3D[{Thick, Line[{{-5, -13, 15}, {5, 7, -5}}]}]
and finally
Show[plane, point, line]
will give you the whole picture.
I'm sure there are other ways to do it, but this will help (I hope).
-Tomas
> Date: Sat, 14 Jan 2012 02:57:17 -0500
> From: harryhar800 at gmail.com
> Subject: Vectors
> To: mathgroup at smc.vnet.net
>
> Hi All,
>
> I'm a math senior high school teacher, and I wish to understand how
> using mathematica 7 to find "h" and the intersection point between the
> plane 6x-2y+z=11 which contains the line x-1 = (y+1)/2 = (z-3)/h. Also
> how to plot/show it visually in 3D graph.
>
> Many thank's.
>
> Harry.
>
- References:
- Vectors
- From: Harry Har <harryhar800@gmail.com>
- Vectors