Mathematica 9 is now available
Services & Resources / Wolfram Forums / MathGroup Archive
-----

MathGroup Archive 2012

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: finding inverses of functions

  • To: mathgroup at smc.vnet.net
  • Subject: [mg126441] Re: finding inverses of functions
  • From: "djmpark" <djmpark at comcast.net>
  • Date: Thu, 10 May 2012 05:00:52 -0400 (EDT)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • References: <4767427.124602.1336550815297.JavaMail.root@m06>

An interesting problem. I'm going to take your "e" to be Exp. Let's define
the y function:

Clear[x, y];
y[x_] := 3 x^3 + 2 E^(2 x); 

The function looks to be monotonically increasing. 

Plot[y[x], {x, -2, 2}] 

And we can verify it. 

ForAll[x, D[y[x], x] > 0]
Resolve[%, Reals] 
...
True

We will solve a differential equation and need an initial condition:

y[0]
2

Write the inverse slope in terms of x[y] and solve the differential
equation.

Clear[x]
x'[y] == 1/(D[y[x], x] /. x -> x[y]);
xsol = DSolve[%, x, y][[1, 1]] 

x -> Function[{y}, InverseFunction[2 E^(2 #1) + 3 #1^3 &][y + C[1]]]

Solve the initial condition for C[1].

x[2] == 0 /. xsol;
Solve[%, C[1]][[1, 1]] 
C[1] -> 0 

We can now define the x function. It is in terms of an InverseFunction but
easily evaluable.

x[y_] = x[y] /. (xsol /. C[1] -> 0)
InverseFunction[2 E^(2 #1) + 3 #1^3 &][y] 

We can check numerically that the function is inverse, at least for small or
exact values of x.

x[y[x]] == x;
% /. x -> 10
True

(I wish I knew a method to show this symbolically.)

We can plot the y function, inverse x function and their composition to
check, at least numerically, the proper relation.

Show[
 {Plot[y[x], {x, -2, 2}, PlotStyle -> Black],
  Plot[x[y], {y, -20, 20}, PlotStyle -> Blue],
  Plot[y[x[z]], {z, -10, 10}, PlotStyle -> Red]},
 AspectRatio -> Automatic,
 PlotRange -> 10,
 Axes -> False,
 Frame -> True] 


David Park
djmpark at comcast.net 
http://home.comcast.net/~djmpark/index.html 


From: John Accardi [mailto:accardi at accardi.com] 

Hello,  I am trying to get Mathematica to find the inverse of:

y = 3x^3 + 2e^(2x)  (which I know is invertible)

InverseFunction only seems to give inverses of built-ins, like Sine.

I tried: 

Solve[ y == 3x^3 + 2e^(2x), x ] but get a message that Solve does not have
methods suitable.  (Solve works for simpler functions, however.)

Any ideas?  Thanks.




  • Prev by Date: Re: Typesetting built-in functions without evaluating
  • Next by Date: Speed of Mathematica on AMD machines
  • Previous by thread: Re: finding inverses of functions
  • Next by thread: installing cdf-reader on chrome under linux?