MathGroup Archive 2012

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: How to add a Locator (Tooltip) to RootLocusPlot?


rlPlt = RootLocusPlot[
   k (s^2 + 2 s + 4)/
     (s (s + 4) (s + 6) (s^2 + 14/10 s + 1)),
   {k, 0, 150}];

roots[s_, loc_] = Solve[
   loc (s^2 + 2 s + 4)/
      (s (s + 4) (s + 6) (s^2 + 14/10 s + 1)) == -1,
   s];

Manipulate[
 Show[
  rlPlt,
  Graphics[{Gray, AbsolutePointSize[8],
    Tooltip[Point[#],
       "k==" <> ToString[loc]] & /@
     ({Re[s], Im[s]} /.
       roots[s, loc])}]],
 {{loc, 50, "Gain (k)"}, .5, 150, .5,
  Appearance -> "Labeled"}]


Bob Hanlon


On Sat, Nov 10, 2012 at 2:09 AM, Eduardo Mendes <emammendes at hotmail.com> wrote:
> Hello
>
> I wonder whether someone out there would know how to add a Locator or
> Tooltip or something else that allows me to see the values of the
> parameter k (See command below) when the mouse passes over the resulting
> curves? Unfortunately I have no idea on how to do it.
>
>
> RootLocusPlot[k (s^2+2 s+4)/(s(s+4)(s+6)(s^2+1.4s+1)),{k,0,150}]
>
> Many thanks
>
> Ed
>
>
>



  • Prev by Date: Re: piecewise and if
  • Next by Date: Manipulating a list with unknown number of elements.
  • Previous by thread: How to add a Locator (Tooltip) to RootLocusPlot?
  • Next by thread: Re: How to add a Locator (Tooltip) to RootLocusPlot?