Re: Fourier Transform of a "step" function
- To: mathgroup at smc.vnet.net
- Subject: [mg128507] Re: Fourier Transform of a "step" function
- From: Bob Hanlon <hanlonr357 at gmail.com>
- Date: Thu, 25 Oct 2012 23:34:07 -0400 (EDT)
- Delivered-to: l-mathgroup@mail-archive0.wolfram.com
- Delivered-to: l-mathgroup@wolfram.com
- Delivered-to: mathgroup-newout@smc.vnet.net
- Delivered-to: mathgroup-newsend@smc.vnet.net
- References: <20121025054335.0BFEB68B5@smc.vnet.net>
f[x_] = Piecewise[
{{a + b x + c x^2, 0 < x < 20}}, 0];
g[w_] = FourierTransform[f[x], x, w] //
FullSimplify
-((1/(Sqrt[2*Pi]*w^3))*
(I*(2*c - w*(I*b + a*w) +
E^(20*I*w)*(-2*c +
I*(b + 40*c)*w +
(a + 20*(b + 20*c))*w^2))))
f2[x_] = InverseFourierTransform[g[w], w, x]
(1/2)*(a + x*(b + c*x))*
(Sign[20 - x] + Sign[x])
f2 differs from the original function only on the step transitions
Simplify[f2[x], #] & /@
{x < 0, x == 0, 0 < x < 20, x == 20, x > 20}
{0, a/2, a + x*(b + c*x),
(1/2)*(a + 20*(b + 20*c)), 0}
f2 has the same Fourier transform as the original function
g[w] == FourierTransform[f2[x], x, w]
True
Bob Hanlon
On Thu, Oct 25, 2012 at 1:43 AM, <etaghtron at gmail.com> wrote:
> Dear Group,
>
> I am new to Mathematica. So question might be naive.
>
> I have a function, which is defined in this form
>
> F(x) = a + b x + c x^2(0 < x < x0)
> F(x) = 0 (x > x0)
>
> This function is simple. However, its Fourier transform is not straightforward due to the limits of the function. I probably can do it manually, but I have a few other functions that are more complex than this one, which also requires Fourier transform. So I'd like to know if Mathematica can handle this.
>
> If you could please shed some light on this, I would be really grateful.
>
> Best Regards,
> Frank
>
- References:
- Fourier Transform of a "step" function
- From: etaghtron@gmail.com
- Fourier Transform of a "step" function