       Re: Integral of Associated Legendre polynomial

• To: mathgroup at smc.vnet.net
• Subject: [mg114838] Re: Integral of Associated Legendre polynomial
• From: Bob Hanlon <hanlonr at cox.net>
• Date: Sun, 19 Dec 2010 05:10:50 -0500 (EST)

```Probably not what you are looking for but...

seq = Table[
Integrate[LegendreP[n, 2, x]/(1 - x^2), {x, -1, 1}],
{n, 20}];

FindSequenceFunction[seq, n] // Simplify

(1/2)*(1 + (-1)^n)*n*(1 + n)

Table[{n,
Integrate[LegendreP[n, 2, x]/(1 - x^2), {x, -1, 1}] ==
(1/2)*(1 + (-1)^n)*n*(1 + n)},
{n, -5, 5}]

{{-5, False}, {-4, False}, {-3, False}, {-2, False}, {-1, True}, {0,
True}, {1, True}, {2, True}, {3, True}, {4, True}, {5, True}}

Consequently, the result is not true for negative n. For negative n,

seq2 = Table[
Integrate[LegendreP[-n, 2, x]/(1 - x^2), {x, -1, 1}],
{n, 20}];

FindSequenceFunction[seq2, n] /. n -> -n

(1/2)*(-1 + (-1)^(-n))*(-1 - n)*n

Combining the two results

f[n_Integer] := (1/2)*(1 + Sign[n] (-1)^n)*n*(n + 1)

And @@ Table[
Integrate[LegendreP[n, 2, x]/(1 - x^2), {x, -1, 1}] == f[n],
{n, -20, 20}]

True

Bob Hanlon

---- "Dr. C. S. Jog" <jogc at mecheng.iisc.ernet.in> wrote:

=============
Hi:

When I give the command

Assuming[n \[Element] Integers,
Integrate[LegendreP[n,2,x]/(1-x^2),{x,-1,1}]]

I get

LegendreP[n, 2, x]
Integrate[------------------, {x, -1, 1}]
2
1 - x

However, if I put specific values of n such as 4,5 etc, I do get the