MathGroup Archive 2012

[Date Index] [Thread Index] [Author Index]

Search the Archive

Re: OutputResponse issue

  • To: mathgroup at smc.vnet.net
  • Subject: [mg128918] Re: OutputResponse issue
  • From: Bob Hanlon <hanlonr357 at gmail.com>
  • Date: Tue, 4 Dec 2012 04:10:30 -0500 (EST)
  • Delivered-to: l-mathgroup@mail-archive0.wolfram.com
  • Delivered-to: l-mathgroup@wolfram.com
  • Delivered-to: mathgroup-newout@smc.vnet.net
  • Delivered-to: mathgroup-newsend@smc.vnet.net
  • References: <20121202095840.E142D6877@smc.vnet.net>

Recommend that the label for the second control be entered either as

	ToString[Subscript[T, s],TraditionalForm]

or just

	Subscript[T, s]


Bob Hanlon


On Mon, Dec 3, 2012 at 1:29 PM, Eduardo M. A. M. Mendes
<emammendes at gmail.com> wrote:
> Dear Bob
>
> I have modified the functions you sent me and it seems that they work ok now.   Would you mind testing them, please?
>
> ClearAll[respPlt1];respPlt1[tmax_,k_]:=OutputResponse[TransferFunctionModel[k/(k+2 s+3 s^2+s^3),s],UnitStep[t],{t,0,tmax}]//FullSimplify;
> Plot[Evaluate[Table[Tooltip[Evaluate@respPlt1[30,k],"k = "<>ToString[k]],{k,0.53 {1,2,3}}]],{t,0,30},PlotRange-> All,Frame->True,Axes->False,FrameLabel->(Style[#,Bold,14]&/@{"t","Output  Response\n"})]
>
>
> and
>
> ClearAll[respPlt2];
> respPlt2[tmax_,k_]:=OutputResponse[TransferFunctionModel[k/(k+2 s+3 s^2+s^3),s],UnitStep[t],{t,0,tmax}]//FullSimplify
> Manipulate[
> Plot[Evaluate[respPlt2[tVal,k]],{t,0,tVal},Frame->True,Axes->False,PlotRange->{0,1.5},FrameLabel->(Style[#,Bold,14]&/@{"t","Output  Response\n"})],{{k,0.53},.05,2.5,.01,Appearance->"Labeled"},{{tVal,30,"Subscript[T, s]"},5,100,1,Appearance->"Labeled"}]
>
>
> The key point seems to be {t,0,tmax} on the function that uses OutputResponse.
>
> Many thanks
>
> Ed
>
>
> On Dec 3, 2012, at 7:03 AM, Bob Hanlon <hanlonr357 at gmail.com> wrote:
>
>> outResponse[k_: 0.53, t_] =
>>  OutputResponse[
>>    TransferFunctionModel[
>>     k/(k + 2 s + 3 s^2 + s^3), s],
>>    UnitStep[t], t] // FullSimplify;
>>
>> Plot[
>> Evaluate[
>>  Table[
>>   Tooltip[
>>    outResponse[k, t],
>>    "k = " <> ToString[k]],
>>   {k, 0.53 {1, 2, 3}}]],
>> {t, 0, 10},
>> Frame -> True, Axes -> False,
>> FrameLabel -> (Style[#, Bold, 14] & /@
>>    {"t",
>>     "Output  Response\n"})]
>>
>> Manipulate[outResponse[k_, t_] =
>>  OutputResponse[
>>    TransferFunctionModel[
>>     k/(k + 2 s + 3 s^2 + s^3), s],
>>    UnitStep[t], t] // FullSimplify;
>> Plot[
>>  Chop[outResponse[k, t]],
>>  {t, 0, 10},
>>  Frame -> True, Axes -> False,
>>  PlotRange -> {0, 1.5},
>>  FrameLabel -> (Style[#, Bold, 14] & /@
>>     {"t",
>>      "Output  Response\n"})],
>> {{k, 0.53}, .05, 2.5, .01,
>>  Appearance -> "Labeled"}]
>>
>>
>> Bob Hanlon
>>
>>
>> On Sun, Dec 2, 2012 at 4:58 AM, Eduardo M. A. M. Mendes
>> <emammendes at gmail.com> wrote:
>>>
>>> Hello
>>>
>>> Can anyone help me with the following issue?
>>>
>>> Plot[Chop at OutputResponse[TransferFunctionModel[0.53/(0.53+2 s+3 s s+s s s),s],UnitStep[t],t],{t,0,10}]
>>>
>>> which returns
>>>
>>> OutputResponse::nsymb :  "0.0002042857142857143` must be a symbol. \
>>> =91=99=98ButtonBox["",
>>> Appearance->{Automatic, None},
>>> BaseStyle->"Link",
>>> ButtonData:>"paclet:ref/OutputResponse",
>>> ButtonNote->"OutputResponse::nsymb"]"
>>>
>>> and several other msgs.
>>>
>>> I have tried a different approach
>>>
>>> restfmf[t_,k_]:=OutputResponse[TransferFunctionModel[(k 1.06)/(k 1.06+2 s+3 s s+s s s),s],UnitStep[t],t];
>>>
>>> Plot[Chop@Evaluate@restfmf[t, 0.5], {t, 0, 10}]
>>>
>>> but got the same error messages
>>>
>>> What am I missing here?
>>>
>>> Many thanks
>>>
>>> Ed
>>>
>>>
>>>
>>
>



  • Prev by Date: Re: V9 !!!
  • Next by Date: Re: Default font in Mathematica 9
  • Previous by thread: Re: OutputResponse issue
  • Next by thread: Find all roots of an interpolating function (solution of a