Re: help to plot..please
- To: mathgroup at smc.vnet.net
- Subject: [mg28496] Re: [mg28485] help to plot..please
- From: BobHanlon at aol.com
- Date: Sun, 22 Apr 2001 21:03:14 -0400 (EDT)
- Sender: owner-wri-mathgroup at wolfram.com
eqn = (x^2 + y^2 == 4);
eqnr = (x^2 + y^2 == r^2);
Method 1:
Plot[Evaluate[y /. Solve[eqn, y]], {x, -2, 2}, AspectRatio -> Automatic,
PlotStyle -> RGBColor[1, 0, 0]];
Off[Plot::"plnr"];
Plot[Evaluate[Table[y /. Solve[eqnr, y], {r, 1/4, 2, 1/4}]], {x, -2, 2},
AspectRatio -> Automatic,
PlotStyle -> RGBColor[1, 0, 0]];
Method 2:
Needs["Graphics`ImplicitPlot`"];
ImplicitPlot[eqn, {x, -2, 2}, PlotStyle -> RGBColor[1, 0, 0]];
ImplicitPlot[Table[eqnr, {r, 1/4, 2, 1/4}], {x, -2, 2},
PlotStyle -> RGBColor[1, 0, 0]];
Method 3:
ParametricPlot[{2*Cos[t], 2*Sin[t]}, {t, 0, 2*Pi}, AspectRatio -> Automatic,
PlotStyle -> RGBColor[1, 0, 0]];
ParametricPlot[
Evaluate[Table[{r*Cos[t], r*Sin[t]}, {r, 1/4, 2, 1/4}]], {t, 0, 2*Pi},
AspectRatio -> Automatic,
PlotStyle -> RGBColor[1, 0, 0]];
Method 4:
Needs["Graphics`Graphics`"];
PolarPlot[2, {t, 0, 2*Pi}, PlotStyle -> RGBColor[1, 0, 0]];
PolarPlot[Evaluate[Table[r, {r, 1/4, 2, 1/4}]], {t, 0, 2*Pi},
PlotStyle -> RGBColor[1, 0, 0]];
Method 5:
ContourPlot[x^2 + y^2, {x, -2, 2}, {y, -2, 2}];
Method 6:
DensityPlot[x^2 + y^2, {x, -2, 2}, {y, -2, 2}];
Bob Hanlon
In a message dated 2001/4/22 2:02:32 AM, reza at maths.iitkgp.ernet.in writes:
>I am very new user in computer. I am doing Ph.D. in fluid dynamics.
>
>I have no good knowledge to use of mathematica mainly i need to draw
different
>kind graph.
>
>At the first time i want to know how i 'll draw like this type of function.
>
>Ex: x^2+y^2=4, means a circle
>