Re: HypergeometricPFQ - simplification
- To: mathgroup at smc.vnet.net
- Subject: [mg89317] Re: HypergeometricPFQ - simplification
- From: sashap <pavlyk at gmail.com>
- Date: Thu, 5 Jun 2008 00:44:29 -0400 (EDT)
- References: <g1gqir$1fn$1@smc.vnet.net>
On May 27, 2:16 pm, janos <janostothmeis... at gmail.com> wrote:
> Could anyone show using Mathematica that the expression
>
> -2/27 + (253*HypergeometricPFQ[{-1/2, -1/6, 1/6}, {4/3, 5/3}, -1/729])/
> 108 - (911*HypergeometricPFQ[{1/2, 5/6, 7/6}, {7/3, 8/3}, -1/729])/
> 6298560 +
> (73*HypergeometricPFQ[{3/2, 11/6, 13/6}, {10/3, 11/3}, -1/729])/
> 9795520512
>
> is equal to
>
> (-2*(-1 + 10*Sqrt[10]))/27? (Using, say, TraceInternal, to see what is
> going on.)
>
> Thank you,
>
> Janos
Dear Janos,
A way to prove this in Mathematica takes couple of lines of code:
In[1]:= $Version
Out[1]= "6.0 for Microsoft Windows (32-bit) (March 13, 2008)"
(* your expression *)
In[2]:= expr = -(2/27) +
253/108 HypergeometricPFQ[{-(1/2), -(1/6), 1/6}, {4/3, 5/3}, -(1/
729)] - (
911 HypergeometricPFQ[{1/2, 5/6, 7/6}, {7/3, 8/3}, -(1/729)])/
6298560 + (
73 HypergeometricPFQ[{3/2, 11/6, 13/6}, {10/3, 11/3}, -(1/729)])/
9795520512;
Now define
In[3]:= e1 = ({D[
HypergeometricPFQ[{-(1/2), -(1/6), 1/6 + a} - 1, {4/3, 5/3} -
1, -z^3], z],
D[HypergeometricPFQ[{-(1/2), -(1/6), 1/6 + a} - 1, {4/3, 5/3} -
1, -z^3], z, z],
D[HypergeometricPFQ[{-(1/2), -(1/6), 1/6 + a} - 1, {4/3, 5/3} -
1, -z^3], z, z, z]} /. {a -> 0, z -> 1/9} // Expand)
Out[3]= {(35/144)*
HypergeometricPFQ[{-(1/2), -(1/6), 1/6}, {4/3, 5/3}, -(1/729)],
(35/8)*
HypergeometricPFQ[{-(1/2), -(1/6), 1/6}, {4/3,
5/3}, -(1/729)] - (7*
HypergeometricPFQ[{1/2, 5/6, 7/6}, {7/3, 8/3}, -(1/729)])/
124416, (315/8)*
HypergeometricPFQ[{-(1/2), -(1/6), 1/6}, {4/3, 5/3}, -(1/729)] -
(7*HypergeometricPFQ[{1/2, 5/6, 7/6}, {7/3, 8/3}, -(1/729)])/
2304 +
(35*HypergeometricPFQ[{3/2, 11/6, 13/6}, {10/3,
11/3}, -(1/729)])/214990848}
Now repeat the same with variable a set to 0 from the outset:
In[4]:= e2 =
FullSimplify[
With[{a = 0}, {D[
HypergeometricPFQ[{-(1/2), -(1/6), 1/6 + a} - 1, {4/3, 5/3} -
1, -z^3], z],
D[HypergeometricPFQ[{-(1/2), -(1/6), 1/6 + a} - 1, {4/3, 5/3} -
1, -z^3], z, z],
D[HypergeometricPFQ[{-(1/2), -(1/6), 1/6 + a} - 1, {4/3, 5/3} -
1, -z^3], z, z, z]}] /. z -> 1/9]
Out[4]= {Sqrt[
11236809 + 778034 Sqrt[73] -
2000 Sqrt[12368090 + 7780340 Sqrt[73]]]/1458,
7/324 Sqrt[
21873 + 10658 Sqrt[73] - 200 Sqrt[-781270 + 106580 Sqrt[73]]],
35/36 Sqrt[73/2 (15 + Sqrt[73]) + 10 Sqrt[5 (595 + 73 Sqrt[73])]]}
Now solve for hypergeometric functions:
In[7]:= ru =
Thread[Union[Cases[e1, _HypergeometricPFQ, Infinity]] -> {h1, h2,
h3}];
and substitute back into your original expression:
In[8]:= FullSimplify[
expr /. (Solve[((e1 - e2) /. ru) == 0, {h1, h2, h3}] /. (Reverse /@
ru))]
Out[8]= {2/27 (-1 + 10 Sqrt[10])}
Hope this helps,
Oleksandr Pavlyk
Wolfram Research